Directory of image this file is from
This file as a plain text file

*20
	PMODE
/PROGRAM CONSTANTS, PAGE ZERO
	*20
C212,	212
C215,	215
C260,	260
RESP,	0
PWTABL,	PATRN-2		/AD-2 OF PW TABL
LOCHAR,	0		/DISPLAY POINTER
TIPE,	TYPE
MASKIT,	MASK
M6,	-6
C10,	10
WSIZE,	0
C2000,	2000
NFRAME,	0
ISETUP,	SETUP
SHOWIT,	WINDOW
/PROGRAM CONSTANTS FOR RANDOM&SHUFFLE
K7,	7
TEMP,	0
R1,	0
R2,	0
R3,	0
INDEX6,	0
RNDM3,	0
RNDM2,	0
RNDM1,	RNDM
SH1,	0
SH2,	0
SH3,	0
SHUFEL,	SHUFL
RMNDR,	RMNDRX
HOLD,	0
ILAB,	GO+3
C20,	20
D72,	110
MD36,	-44
NTRIAL,	0
TT,	0
ITRIAL,	TRIAL
IGO,	GO
C40,	40
ILL,	LL
TBLK,	0
NBLOCK,	0
FCLOCK,	2100		/100KHZ CLOCK
RFRESH,	0		/-REFR. RATE
RNX,	RN
IRX,	IR
K1000,	1000
/DISPLAY PARAMETERS
WINDSP,	1		/CHAR SPACING
VERCO,	340		/VERT DISP COOR
IHORCO,	240
LMHC,	0
RMHC,	0
HCWIND,	0
MASKSP,	2
MOVE,	11
LSIZE,	-20
RSIZE,	-6
SLSIZE,	-20		/FIRST FRAME L M
SRSIZE,	-6		/LAST FRAME R M
ONCE,	0
ILLL,	LLL
IRECRD,	RECORD
DOT,	40		/DUMMY CHAR="X"
TIMER,	0
AEXPOS,	PATRN		/AD+1 COND EXPS
LASTTR,	TCONDS+107
TIME,	0		/-CURRENT EXPOSE
PAUSET,	-144		/NO FRAMES PAUSE
NTIME,	0
WIDE,	0
M7,	-7
ADNMTL,	4234
ADTRL1,	TCONDS-1
ADSET1,	CHRSET-1
TOTCOR,	0
STRNG0,	STRING-1
TOLONG,	4400
RT,	0
IBLOCK,	BLOCK
SIGNAL,	0
SIG0,	24		/SIGNAL=T
SIG1,	6		/SIGNAL=F
CORESP,	0
BOTRES,	50
RESP0,	40		/"T" RESP
RESP1,	10		/"F" RESP
SRESP,	1000		/START SIGNAL
TYPE,	0
	TLS
	TSF
	JMP .-1
	CLA
	JMP I TYPE
/SUBR CLEARS AND RESTARTS MSEC CLOCK
CLOCK,	0
	CLA
	CLLR
	TAD FCLOCK
	CLLR
	CLA
	JMP I CLOCK
DELAY,	0
	CLCA
	TAD RFRESH
	SPA CLA
	JMP .-3
	CLLR
	JMP I DELAY
/SUBR SETS HCS RELATIVE TO LMHC
SETUP,	0
	CLA
	TAD LSIZE
	CIA
	CLL RTL
	TAD MASKSP
	TAD LMHC
	DCA HCWIND
	TAD WSIZE
	DCA TEMP
	SKP
	TAD WINDSP
	TAD C10
	ISZ TEMP
	JMP .-3
	TAD MASKSP
	TAD HCWIND
	DCA RMHC
	JMP I SETUP
/SUBR DISPLAYS MASK FRAME
MASK,	0
	CLA
	DCA ONCE
	TAD LSIZE
	SMA
	JMP RIGHT
	DCA NTIME
	TAD LMHC
	DCA 1
	TAD VERCO
MASKON,	LINC
	LMODE
	DSC I 0
	7777
	PDP
	PMODE
	ISZ NTIME
	JMP MASKON
	CLA
	TAD ONCE
	SZA
	JMP I MASK
RIGHT,	ISZ ONCE
	TAD RSIZE
	SMA
	JMP I MASK
	DCA NTIME
	TAD RMHC
	JMP MASKON-2
/WINDOW DISPLAY ROUTINE
WINDOW,	0
	CLA
	TAD WSIZE
	DCA NTIME
	TAD HCWIND
	DCA 1
	TAD LOCHAR
	DCA 11
WNEXT,	TAD I 11
	CLL RAL
	TAD PWTABL
	TAD C2000	/BIT 1: USE LDF
	DCA 2
	TAD VERCO
	LINC
	LMODE
	DSC 2
	DSC I 2
	PDP
	PMODE
	ISZ NTIME
	SKP
	JMP I WINDOW
	CLA
	TAD WINDSP
	TAD 1
	DCA 1
	JMP WNEXT
/PROGRAM STARTS HERE
	PAGE
START,	CLA
	LINC
	LMODE
	LDF 2
	ESF
	PDP
	PMODE
/INIT R.N. GENERATOR BY SETTING BIT 0 
	ISZ TEMP
	NOP
	LAS
	SZA CLA
	JMP .-4
	JMS I IRX
	JMS I RNX
	ISZ TEMP
	JMP .-2
	HLT		/STOP WHEN READY
/SESSION STARTS HERE WITH A WARMUP BLOCK
/OF 16 TRIALS FOLLOWED BY K SCORED BLOCK
/OF 72 TRIALS EACH; K=R SWS; EACG SCORED
/BLOCK SAVED ON MAG TAPE UNIT 0 IN
/CONSECUTIVE TBLKS STARTING AT L SWS
SESSON,	LINC
	LMODE
	LSW
	STC TBLK
	PDP
	PMODE
	LAS
	CIA
	DCA NBLOCK
	TAD C20
	JMS I IBLOCK
RUN,	DCA I ADNMTL	/0-NO MISTRIALS
	DCA TOTCOR
	TAD D72
	JMS I IBLOCK
/NOW SAVE SCORED BLOCK ON TBLK & UP,
/1 BLOCK/TBLK. SAVED AS FOLLOWS:
/4000-4107:RESP FOR EACH OF 72 TRIAL
/TYPES; 4110-4217:72 CORRESPONDING RTS
/4220-4225:6 R.R.S;4226-4233 6 F.T.S
/4234:NO. MISTRIALS
	CLA STL RAR
	TAD TBLK
	DCA  WRITE2
	LINC
	LMODE
	LDF 2
	WRC U
WRITE2,	0
	PDP
	PMODE
	CLA
	ISZ TBLK
/TYPE OUT TOTAL CORRECT FOR BLOCK AS 3-
/DIGIT OCTAL NUMBER
	TAD C212
	JMS I TIPE
	TAD C215
	JMS I TIPE
	TAD TOTCOR
	RTR
	RTR
	RTR
	AND K7
	TAD C260
	JMS I TIPE
	TAD TOTCOR
	RTR
	RAR
	AND K7
	TAD C260
	JMS I TIPE
	TAD TOTCOR
	AND K7
	TAD C260
	JMS I TIPE
	ISZ NBLOCK
	JMP RUN
	HLT
	JMP .-1
/SUBR RUNS UP TO 72 TRIAL BLOCK; NO. OF
/TRIALS=AC ARGUMENT
BLOCK,	0
	CIA
	DCA NTRIAL
	TAD MD36
	DCA 7
	TAD ADTRL1
	DCA SH1
	TAD D72
	DCA SH2
	STA
	DCA SH3
	JMS I SHUFEL	/SHUFFLE TRIALS
	ISZ 7
	JMP .-10
	TAD ADTRL1
	DCA 10
/EACH TRIAL BEGINS HERE
TRIAL,	TAD I 10
	DCA TT		/TRIALTYPE=
	TAD TT		/36*KEY(0,1)+6*
	TAD MD36	/WIDTH+KEY POSN
	SMA
	JMP S0		/KEY=1
	CLA
	TAD TT
	DCA 1
	TAD SIG0
	DCA SIGNAL	/KEY ASCII CODE
	TAD RESP0
	JMP S1
S0,	DCA 1
	TAD SIG1
	DCA SIGNAL
	TAD RESP1
S1,	DCA CORESP	/-CORRECT RESP
/SHUFFLE CHAR STRING
	STA CLL RTL
	DCA 7
	TAD ADSET1
	DCA SH1
	STL IAC RTL
	DCA SH2
	STA
	DCA SH3
	JMS I SHUFEL
	ISZ 7
	JMP .-10
	DCA 0
	TAD 1
	TAD M6		/GET WIDTH
	SPA
	JMP .+3
	ISZ 0
	JMP .-4
	TAD K7
	TAD ADSET1	/AD KEY POSN IN
	DCA 5		/LETTER SET
	TAD 0
	CMA
	DCA WSIZE
	TAD ADSET1
	DCA 11
LLL,	TAD I 11	/LOOK FOR A KEY
	CIA		/CHAR IN LAST
	DCA 1		/STRING;REPLACE
	TAD 1		/IT WITH CHAR
	TAD SIG0	/FROM NEW KEY P
	SNA CLA
	JMP .+5
	TAD 1
	TAD SIG1
	SZA CLA
	JMP I ILLL	/JMP .-12
	TAD 11
	DCA 7
	TAD I 5		/REPLACE OLD KEY
	DCA I 7
	TAD SIGNAL
	DCA I 5
/GET FRAMETIME FOR WSIZE AND (USUALLY
/CONSTANT) REFRESH RATE
	TAD WSIZE
	TAD AEXPOS
	DCA 1
	TAD I 1
	DCA TIME
	TAD M6
	TAD 1
	DCA 1
	TAD I 1
	DCA RFRESH
/ENCODES NEXT TEXT STRING WHICH CONSISTS
/OF (W-1)LEADING X"S, 1 LEADING BLANK,
/THE SIX INTERVENING LETTERS=STIMULUS
/1 TRAILING BLANK, AND (W-1) TRALING X"S
	TAD WSIZE
	DCA WIDE
	TAD STRNG0	/AD-1 STRING
	DCA 11
	ISZ WIDE
	SKP
	JMP .+4
	TAD DOT
	DCA I 11
	JMP .-5
	TAD C40
	DCA I 11
	TAD M6
	DCA WIDE
	TAD ADSET1
	DCA 12
	TAD I 12
	DCA I 11
	ISZ WIDE
	JMP .-3
	TAD C40
	DCA I 11
	TAD WSIZE
	DCA WIDE
	ISZ WIDE
	SKP
	JMP .+4
	TAD DOT
	DCA I 11
	JMP .-5
	TAD STRNG0
	DCA LOCHAR	/AD-1 IST CHAR
/ALIGN RIGHT MASKS=BALANCED FIXATION
	TAD WSIZE
	DCA WIDE
	ISZ WIDE
	SKP
	JMP .+4
	TAD C10
	TAD WINDSP
	JMP .-5
	CIA
	TAD IHORCO
	DCA LMHC
	JMS I ISETUP	/SET H.C.S
/FOR FIRST FRAME HAVE SPECIAL LEFT MASK
/LENGTH IN CASE NO PRIOR WIDTH INFO.
	TAD LSIZE
	DCA 16		/SAVE LSIZE
	TAD SLSIZE
	DCA LSIZE
/SHOW FIRST FRAME UNTIL S SIGNALS READY
/AND THEN FOR -PAUSET MSECS
	6304		/CLR RESP PANEL
LL,	JMS CLOCK
	JMS I MASKIT	/JMS WINDOW
	JMS I SHOWIT
	JMS DELAY
	6302		/READY YET?
	AND SRESP
	SNA CLA		/RESP YET?
	JMP I ILL	/JMP .-7=LL
	TAD PAUSET
	DCA TIMER
	JMS CLOCK
	JMS I MASKIT
	JMS I SHOWIT
	JMS DELAY
	ISZ TIMER
	JMP .-5
	TAD M7
	TAD WSIZE
	DCA NFRAME	/7+COND FRAMES
	TAD 16
	DCA LSIZE	/RESTORE LSIZE
/EACH FRAME BEGINS HERE
GO,	JMS I ISETUP	/LOOP THRU FRAME
	TAD TIME
	DCA TIMER
	JMS CLOCK	/RESTART CLOCK
	JMS I MASKIT
	JMS I SHOWIT	/DISPLAY FRAME
	JMS DELAY
	ISZ TIMER
	JMP .-5
	ISZ NFRAME	/ANOTHER FRAME?
	SKP
	JMP DONE
	TAD MOVE	/SLIDE FRAME
	TAD LMHC
	DCA LMHC	/NEW H.C.S
	ISZ LOCHAR	/SLIDE STRING
	JMP I IGO	/JMP GO
/DISPLAY DONE: SHOW LAST FRAME UNTIL RES
/USE SPECIAL-SIZED RIGHT MASK
DONE,	TAD RSIZE
	DCA 16
	TAD SRSIZE
	DCA RSIZE
	TAD TOLONG	/-MAX RT
	DCA RT		/0 RT COUNTER
	6314		/AND RESP PANEL
	JMS CLOCK
	JMS I MASKIT
	JMS I SHOWIT
	JMS DELAY
	6312
	AND BOTRES	/IGNORE INVALID
	SZA
	JMP I IRECRD	/JMP RECORD
	ISZ RT
	JMP .-11
MTRIAL,	ISZ I ADNMTL	/INCR NO MISTRLS
	TAD 10		/RERUN TRIAL AT
	DCA 6		/END OF BLOCK
	TAD I LASTTR
	DCA I 6
	TAD TT
	DCA I LASTTR
	STA
	TAD 10
	DCA 10
	JMP I ITRIAL
RECORD,	AND CORESP
	SZA CLA		/CORRECT RESP=1
	IAC		/INCORRECT=0
	DCA RESP
	TAD PAUSET
	TAD PAUSET	/LEAVE DISPLAY
	DCA TIMER	/ON BRIEFLY
	JMS CLOCK
	JMS I MASKIT
	JMS I SHOWIT
	JMS DELAY
	ISZ TIMER
	JMP .-5
	TAD RESP
	TAD TOTCOR
	DCA TOTCOR	/NO CORR IN BLOK
	STL RAR
	TAD TT
	DCA 6		/SAVE RESULTS
	TAD RESP
	DCA I 6		/BY TRIAL TYPE
	TAD 6
	TAD D72
	DCA 6
	TAD TOLONG
	CIA
	TAD RT
	DCA I 6
	ISZ NTRIAL
	JMP I ITRIAL
	TAD I IBLOCK
	DCA .+2
	JMP I .+1	/JMP I BLOCK
	0		/HOLDS RET. ADR.
/ARRAY WHICH STORES 72 TRIAL TYPE CODES
TCONDS,	0
	44
	1
	45
	2
	46
	3
	47
	4
	50
	5
	51
	6
	52
	7
	53
	10
	54
	11
	55
	12
	56
	13
	57
	14
	60
	15
	61
	16
	62
	17
	63
	20
	64
	21
	65
	22
	66
	23
	67
	24
	70
	25
	71
	26
	72
	27
	73
	30
	74
	31
	75
	32
	76
	33
	77
	34
	100
	35
	101
	36
	102
	37
	103
	40
	104
	41
	105
	42
	106
	43
	107
/CHARACTER SET: T F SIGNAL (0NE IN 
/INITIAL STRING + 5 DISTRACTORS=PEJLI
CHRSET,	20		/P
	24		/T
	5		/E
	14		/L
	12		/J
	11		/I
/STANDARD SET OF EXPOSURES=32 MSEC/CHAR
	*4220
/  REFRESH RATES
	-413		/R.R.6
	-500		/R.R.5
	-413		/R.R.4
	-413		/R.R.3
	-413		/R.R.2
	-413		/R.R.1
/   NO. REFRESHES
	-2		/F.T.6
	-2		/F.T.5
	-3		/F.T.4
	-4		/F.T.3
	-6		/F.T.2
	-14		/F.T.1
/PATTERN WORDS FOR ASCII CODES
PATRN,	4477		/A
	7744
	5177		/B
	2651
	4136		/C
	2241
	4177		/D
	3641
	4577		/E
	4145
	4477		/F
	4044
	4136		/G
	2645
	1077		/H
	7710
	7741		/I
	0041
	4142		/J
	4076
	1077		/K
	4324
	177		/L
	301
	3077		/M
	7730
	3077		/N
	7706
	4177		/O
	7741
	4477		/P
	3044
	4276		/Q
	376
	4477		/R
	3146
	5121		/S
	4651
	4040		/T
	4077
	177		/U
	7701
	176		/V
	7402
	677		/W
	7701
	1463		/X
	6314
	770		/Y
	7007
	4543		/Z
	6151
	4177		/[
	0000
	2040		/\
	0410
	0		/]
	7741
	2000		/^
	2077
	3410		/BACK ARROW
	1010
	0		/SPACE
	0
	7500		/!
	0
	6006		/"
	60
	3614		/NUMBER SIGN
	1436
	7721		/DOLLAR SIGN
	4677
	1446		/%
	6130
	5166		/&
	0523
	500		/APOSTROPHY
	6
	4163		/(
	0
	0		/)
	6341
	2050		/*
	50
	404		/+
	437
	605		/,
	0
	404		/-
	404
	1		/.
	0
	601		//
	4030
	4136		/0
	3641
	2101		/1
	177
	4523		/2
	2151
	4122		/3
	2651
	2414		/4
	477
	5172		/5
	651
	1506		/6
	4225
	4443		/7
	6050
	5126		/8
	2651
	5120		/9
	3651
	4200		/:
	0
	2601		/;
	0
	2410		/<
	0042
	1212		/=
	1212
	4200		/>
	1024
	4020		/?
	2055
/RANDOM PACKAGE BEGINS HERE
	PAGE
RNDM,	0		/RN IN 0,RNDM3
	JMS I RNX	/36 BIT RN
	JMS I RMNDR	/REMAINDR RNDM3
	CLA
	JMP I RNDM	/DONE
M36,	-44		/
IDX1,	0		/
R1X,	0		/
R2X,	0		/
R3X,	0		/
RMNDRX,	0		/GET RMNDR
	CLA		/
	DCA RNDM2	/
	TAD R1		/
	DCA R1X		/
	TAD R2		/
	DCA R2X		/
	TAD R3		/
	DCA R3X		/
	TAD M36		/
	DCA IDX1	/FOR 36 BITS
RMN1,	CLA		/
	TAD RNDM2	/
	CLL		/