*20
///JSGLITCH
/PROGRAM TO EXAMINE FOURIER
/DATA FOR GLITCHES
/
/CALLED AFTER JSDATA
/
/DISPLAYS SEQUENTIAL SEGMENTS
/AND WAITS FOR OPERATOR TO
/ANSWER YES OR NO
/
/IF THE ANSWER IS NO
/THE BLOCK OF DATA IS SET TO ZERO
/
/
/AT END OF PROGRAM:
/XXXX BAD BLOCKS
/XXXX GOOD BLOCKS
/XXXX TOTAL BLOCKS
/IS PRINTED
/CONTROL RETURNS TO JSDATA
/
/
	SEGMNT 5
	*20
/GET HEADER BLOCK
/
	LDF 6
	JMP SETXT
	RDC
	0
	STD
	JMP .-1
	LDA
	2004		/NUM BLOCKS
	STC TOTSEG
	JMP UNSETT
/
OKVIEW,	LDF 6
	SET I 5
	3777
	SET I 6
	-400
	CLR
	STA I 5
	XSK I 6
	JMP .-2
/
	JMP TSTINT
/
FORDIS,	JMP GSEG
	 JMP ENDTST
/
/LISTEN FOR OPERATOR
/
L1,	IOB 11
	7704
	-1
	5
	272
	JMP .-5
/
	IOB 11
	0113
	215
	4
	INBUF
	JMP .-5
/
	IOB 1
	13
	.+3
	JMP .-3
	IOB 5
/
/GOT OPERATOR RESPONSE
/
	LDA I
	TAB-1
	LIF 4
	SCAN
	JMP EOL
	JMP EOL
	JMP EOL
	JMP EOL
	JMP EOL
/
TAB,	YES
	NO
	0
/
EOL,	SAE I
	NO
	SKP
	JMP NGB
	LDA I
	1
	ADM I
GUDCNT,	0
	JMP FORDIS
/
/NO GOOD BLOCK
/
NGB,	LDA I
	1
	ADM I
BADCNT,	0
	JMP SETXT
	LDA
	RXT
	STC WRITIT
/SET TO ZERO
	LDF 6
	SET I 11
	3777
	SET I 10
	-400
	CLR
	STA I 11
	XSK I 10
	JMP .-2
/
	WRC
WRITIT,	0
	STD
	JMP .-1
	JMP UNSETT
	JMP FORDIS
/
/EXTENDED ADDRESS MODE
/TAPE SETUP
/
SETXT,	LDA I
	1031 	/1030 2 TAPE
	AXO
	LDA I
	4000
	TMA
	CLR
	JMP 0
/
UNSETT,	LDA I
	10
	AXO
	CLR
	JMP 0
/
	EJECT
/END OF DISPLAY
/
ENDTST,	IOB 2
	0
	SETWRD
	400
	SFLOAT
	GUDCNT
	OUTPUT
	GMES
	SFLOAT
	BADCNT
	OUTPUT
	BMES
	SFLOAT
	SEGCNT
	OUTPUT
	SEGMES
/
	LIF 4
	MESOUT
	GMES
	LIF 4
	MESOUT
	BMES
	LIF 4
	MESOUT
	SEGMES
/
/RETURN TO JSDATA
/
READIT,	LIF 4
	JMP 40 	/UNCALL
	EJECT
/GET A SEGMENT OF DATA
/
GSEG,	SET 3
	0
	LDF 6
	LDA I
SEGCNT,	0
	SAE I
TOTSEG,	0
	SKP
	JMP 3
	ADA I
	1
	STC SEGCNT
/
	JMP RDNXT
	XSK I 3
	JMP 3
/
/
/
RDNXT,	LDA 
	0
	STC RDNXX
	LDA I
FBLM,	0
	ADA I
	1
	STA
	FBLM
	SAE I
	1000
	SKP
	JMP 3
	STC RXT
	JMP SETXT
	RDE 
RXT,	0
	STD
	JMP .-1
/
	JMP UNSETT
RDNXX,	JMP
	EJECT
/INITIALIZE
/
TSTINT,	SET 3
	0
	IOB 2
	26
/
	IOB 11 	/ENABLE DISPLAY
	26
	0
	5
	DISBUF
	JMP .-5
/
	LDA I
	0 	/500 2 TAPE
	STC FBLM
	STC BADCNT
	STC GUDCNT
	STC SEGCNT
/
	JMP 3
/
/
DISBUF,	-0
	2
	0 	/X
	0 	/Y
	LDF 6
	2000 	/BUFSTART
NDIS,	400	/BUFSIZ
DT3,	0 	/CURSOR
	0		/SCALE
DATSPC,	1 	/DATA SPACING
SCSPAC,	2 	/SCOPSPAC
	0 	/CURSOR RET
	4001
	4000
/
BMES,	0
	0
	TEXT . BAD BLOCKS .
	4543
GMES,	0
	0
	TEXT . GOOD BLOCKS.
	4543
SEGMES,	0
	0
	TEXT . TOTAL BLOCKS .
	4543
	 
/PARAMETER BLOCK ASSIGNMENTS
/
/COMMAND DECODER ASSIGNMENTS
/
/
	YES=17
	NO=20
	INBUF=2325
	UNCALL=JMP 40
	MESOUT=JMP 43
	SCAN=JMP 21
	 
/FLOATING POINT DEFINITIONS.
/
	FAC=0
	OUTPUT=1710
	SFLOAT=1714
	SETWRD=1706
/
/
/JSGLITCH
/JUNE 73