*20
//MOD10
	 
/DECODE MODULE 10
/BLOCK 32
	 
/DIAL PROGRAM HANDLER
/CALLS MODULE 11 AS
/AN OVERLAY TO Q2 FOR
/RUNNING DIAL PROGRAMS
	 
	LODSYM
	 
	SEGMNT 4
	*1400
	10
	 
	ADD COMAND
	ADA I
	JMP .+4
	STC .+2
	STC COMAND
	JMP
/
	JMP DOLD
	JMP CHAN
	JMP RUNH
	JMP OLY
	JMP UNCAL
	JMP CAL
	JMP FND
	JMP COMFL
/
COMFL,	JMP GETRUN
	LDA I
	4\INBUF+1
	JMP GTDILN
	ADD DILUN
	BSE I
	6000
	STC DILUN
	JMP FNDDIL
	JMP BAD 	/NO FIND
/FIND
	JMP RSD2
	JMP COMFL2
FND,	JMP GETPRG
	ADD DILBLK
	STC COMNO
	JMP EX1
	EJECT
CAL,	JMP GETPRG
	JMP IDF
	ADD DFI
	STC UCDF
	IOB I 12
	4134
	IOB I 12
	5135
	IOB I 12
	6136
	IOB I 12
	7137
	LDA
	RETURN
	STC CALRET
	JMP RUNDIL
/
UNCAL,	ADD CALRET
	AZE I
	JMP RSTOP
	STC RETURN
	STC CALRET
	ADD UCDF
	STA
	UC
	BCL I
	40
	STC GSRIF
UC,	LDF
	LDA I
	4134
	JMP LREAD
	JMP GOUSER
/
OLY,	JMP GETPRG
	JMP RUNDIL
	EJECT
RUNH,	JMP GETRUN
	LDA I
	4\INBUF+1
	JMP GTDILN
	JMP FNDDIL
	JMP BAD 	/NO FIND
	JMP RUNDIL 	/FIND
/
CHAN,	FETCH
	STC DILUN
	FETCH
	STC DILBLK
	JMP RUNDIL
/
DOLD,	FETCH
	STC DILUN
	FETCH
	STC DILBLK
	JMP GETRUN
	JMP LODDIL
	JMP LV
	EJECT
/GET MODULE 11
GETRUN,	CLR
	AXO
	IOB 12
	2033
	JMP 0
/
BAD,	TYPE
	QM
	JMP RSD2
	JMP EX2
/
LV,	JMP RSD2
	JMP GOUSER
/
/RESTORE DECODE Q2
RSD2,	CLR
	AXO
	IOB 12
	2022
	JMP 0
	EJECT
GETPRG,	SET 15
	0
	FETCH
	STC DILNAM
	FETCH
	STC DILNAM+1
	FETCH
	STC DILNAM+2
	FETCH
	STC DILNAM+3
	FETCH
	STC DILUN
	JMP FNDDIL
	JMP LV 	/NO FIND
	JMP 15 	/FIND
	EJECT
/SEARCH DIAL INDEX
/ENTER WITH DILNAM
/SET UP
FNDDIL,	SET 14
	0
/DIAL INDEX
	JMP SETUN
	LDH
	4\DILUN
	AZE
	JMP NOTZER
/UNIT ZERO INDEX
	IOB 12
	1034
	IOB 12
	2035
	JMP SRIND
/
NOTZER,	JMP SETUN
	STA
	RZ1
	STC RZ2
/
	LDA I
	400
	TMA
RZ1,	RDC
	346
	LDA I
	1000
	TMA
RZ2,	RDC
	347
/
SRIND,	SET I 17
	-200
	SET I BETA3
	377
	EJECT
NP,	CLR
	STC GFLG
	SET I BETA2
	DILNAM-1
	LDA I BETA2
	SAE I BETA3
	STC GFLG
	SRO I
	3567
	JMP .-5
	LDA I
GFLG,	0
	AZE
	SKP
	APO
	SKP
	JMP MTCH
	XSK I 17
	JMP NP
	JMP RSD
/
MTCH,	LDA
	DILUN
/CHECK MS OR BINARY
	ROL 1
	APO
	JMP .+3
/BINARY
	XSK I BETA3
	XSK I BETA3
	LDA I BETA3
/CHECK EXISTENCE
	SAE I
	5757
	XSK I 14
	STC DILBLK
	 
RSD,	SETAXO
	IOB 12
	1021
	IOB 12
	2022
	LDF 3
	JMP 14
	EJECT
SETUN,	LDA
	0
	STC SETUX
	ADD DILUN
	AZE
	JMP .+6
	LDH
	4\CURUN
	STH
	4\DILUN
	JMP .+3
	STH
	4\CURUN
	ROR 1
	BCL I
	7774
	BSE I
	20
	STA
	AXOL
	BSE I
	1000
	AXO
	LDA
	DILUN
	ROL 3
	BCL I
	7767
	BSE I
	RDC
SETUX,	JMP
	EJECT
RUNDIL,	JMP GETRUN
	JMP LODDIL
	JMP RSD2
	LDA
	DILBLK
	SCR 13
	ADD RLST
	AZE
	JMP DORLST
	LDA
	ACTMP
	LIF 5
	JMP 20
/
DORLST,	LDA
	ACTMP
AA10,	JMP RLST
	 
/
	*1774
RLST,	0
	0
	0
	0
/
/MOD10
/FEB 74
/
/
/
//MOD11
/DECODE MODULE 11
/BLOCK 33
/
/SUPPORT FOR MODULE 10
/CALLED AS OVERLAY TO 
/DECODE Q2
/ASSEMBLE WITH MOD10
/
	SEGMNT 4
	*1000
/
/GET NAME FROM TEXT STRING
/ENTER WITH POINTER IN AC
GTDILN,	STC BETA3
	ADD 0
	STC GTDILX
	SET I BETA2
	4\DILNAM-1
	SET I 17
	-10
PD,	LDH I BETA3
	SHD I
	4300
	JMP FIL77
	SHD I
	4500
	JMP FIL77
	SHD I
	5400
	JMP FIL77
	SHD I
	5600
	JMP FIL77
	STH I BETA2
	XSK I 17
	JMP PD
	LDH I BETA3
	JMP UCHK
	EJECT
FIL77,	CLR
	COM
	STH I BETA2
	XSK I 17
	JMP .-2
/
UCHK,	CLR
	STC DILUN
	LDH BETA3
	SAE I
	54
	SKP
	JMP .+4
	SAE I
	56
	JMP GTDILX-1
	LDH I BETA3
	SAE I
	15
	JMP .+5
	LDA I
	2000
	STC DILUN 	/MANUSCRIPT
	LDH I BETA3
	BCL I
	7770
	BSE I
	4000
	ADD DILUN
	STC DILUN
	CLR
GTDILX,	JMP
	EJECT
/LOAD DIAL FILE
/ASSUME ALL SETUP WITH
/DILBLK AND DILUN
LODDIL,	SET 14
	0
	LDA
	DILBLK
	STC INDX
/
	JMP SETUN
	STA
	DBR
	STC DBI
	LDA I
	400
	TMA
DBI,	RDC
INDX,	0
/
	SET I BETA3
	737
	SET I 17
	-40
	SET I BETA2
	0
/
DBL,	LDA I BETA3
	APO I
	JMP WHOC
	LDA I
	1
	ADD INDX
	STC INDX
/SUPPRESS BELOW BANK 5
	NOP 	/ADD BETA 2
	NOP 	/ADA I
	NOP 	/-23
	NOP 	/APO
	NOP 	/JMP WHOC
	EJECT
/READ IN THE BLOCK
	LDA
	BETA2
	ROL 5
	BCL I
	777
	BSE I
AXOL,	0
	AXO
	LDA
	BETA2
	ROL 10
	BCL I
	377
	TMA
	LDA
	INDX
	STC .+2
DBR,	RDC
	0
/
WHOC,	XSK I BETA2
	XSK I 17
	JMP DBL
	LDF 1
	SET I BETA3
	377
	SET I BETA2
	RLST-1
	SET I 17
	-4
	LDA I BETA3
	STA I BETA2
	XSK I 17
	JMP .-3
/
	SETAXO
	IOB 12
	1021
AA11,	JMP 14
/
/MOD11
/FEB 74