Directory of image this file is from
This file as a plain text file

*20
/PROGRAM MAGSPY
/PDP-12 ASCII SOURCE
/AUTHOR:  C.A.JOHNSON (DEC)
	CLR
	MSC 1
/INITIAL DISPLAY
	SET I 17
	1300
	JMP QAINIT
	TEXT4
	ANS4
	JMP .+2
	JMP START
	XSK I 17
	JMP QARFSH
START, JMP QAINIT
	TEXT1
	ANS1
	JMP QARFSH
/RECOVER USERS OPTION
	LDH
	ANS1+4000
	SAE I
	63
	JMP .+2 /NOT 3
	JMP MONIT
	SAE I
	62
	JMP .+2
	JMP BEGIN /SHOW QA3
/EXPLANATION DISPLAY
	JMP QAINIT
	TEXT2
	ANS2
	JMP QARFSH
/IGNORE ANSWER
/BN, UNIT SELECT DISPLAY
BEGIN,	JMP QAINIT
	TEXT3
	ANS3
	JMP QARFSH
	JMP OVRTEX
TEXT1,	TEXT >FDO ?<1
F 1 EXPLAIN PROGRAM
F 2 BEGIN PROGRAM
F 3 CALL DIAL
F 
H  TO RESTART:
H STOP PROCESSOR
H START LS(4020)\>
ANS1,	7400
	3400
TEXT2,	TEXT >HSENSE SWITCH POSN FUNCTION
H      0       DOWN TEXT
H      0       UP   WAVEFORM
H      1       DOWN SMALL TEXT
H      1       UP   LARGE TEXT
H      2       DOWN TEXT IN OCTAL
H      2       UP   TEXT IN SYMBOLIC
F 
FTYPE LF TO BEGIN
F\>
ANS2,	7400
	0034
TEXT3,	TEXT >FDATA BEGINS
FIN BLOCK <3
F 
FOF UNIT<1\>
ANS3,	7400
	0000
	7400
	3400
TEXT4,	TEXT >FPROGRAM "MAGSPY"
H 
H    (DIGITAL EQ. CORPORATION)\>
ANS4, 0
			/Q+A ROUTINE FOR PDP-12
QAINIT,	LDA I		/SAVE JMP RETURN
	2
	ADD 0
	STA I
QAB,	0		/JMP 	+3
	ADD QAL+3
	STC 1		/PTR TO FIRST PARAM
	LDA 1		/GET FIRST PARAM
	ADD QAQ+1	/PTR TO HALFWORD-1
	STC QAG-3
	LDA I 1
	STC QARFSH-1
	STC 6		/XR6 USED AS A SWITCH. =0 IF NO ANSWER FIELD, =1777 IF YES
QACA,	SET 3
	QARFSH-1
	SET 4		/XR4 TO PTR TO QUESTIONS
	QAG-3
			/TO HERE IF FIRST TIME THROUGH OR FOLLOWING A CR
	SET 1
	4
	JMP QAT
	NOP		/F
	LDH I 4		/H. BUMP PTR IF H OR F
QAD,	JMP QAO
	JMP .+6		/74
	JMP QAE		/34
	SAE I		/CR?
	43
	JMP QAD		/NO
	JMP QACA+4 /EXAMINE NEXT CHAR
			/INITIALIZE ANSWER BUFR
	STH 3		/74 TO ANSWERS
	LDH I 4		/NEXT HALFWORD
	ADA I
	-60
	COM
	STC 6
	STH I 3		/0 IN AC
	XSK I 6
	JMP .-2
	LDH I 3		/BUMP PTR TO ANSWERS
	JMP QAD
			/ANSWER BUFR IS INITIATED
QAE,	STH 3
	SET I 4		/XR4 TO PTR TO LAST TYPED CHAR IN ANSWER BUFR
	0
			/----RE-ENTER HERE TO REFRESH----
QARFSH,	LDA I		/INITIAL Y POSITION
	137 
	STC QAH-1
	SET I 3		/XR3 TO PTR TO HALFWORD QUESTIONS-1
	0
	SET 5		/XR5 TO PTR TO LAST DISPLAYED CHAR IN ANSWER BUFR
	QARFSH-1
QAG,	SET 1
	3
JMP QAT
	JMP .+7		/F
	LDH I 3		/H. BUMP PTR
	LDA I		/NEITHER. ASSUME HALF SIZE
	BCL I
	STC QAM+2	/SET INSTR TO CLEAR FF FOR HALF SIZE
	ADD QAW		/NOP IN AC
	JMP QAM
	LDH I 3		/BUMP PTR
	LDA I
	BSE I
	STC QAM+2	/SET INSTR TO SET FF FOR FULL SIZE
	ADD QAW+1	/ADD 9U IN AC
QAM,	STC QAP+3
	MSC I 4		/EAD CONTROL REGISTER
	BSE I		/THIS INSTR CHANGES. EITHER BSE & OR BCL &
	200
	MSC 4		/AC TO CONTROL REGISTER
	SET I 1		/XR1 TO INITIAL X POSITION
	100
	LDA I		/Y COORDINATE MULTIPLE
	-40
	ADM I		/Y COORDINATE
	0
QAH,	LDH I 3
	JMP QAO+1
	JMP QAZ		/74 BUMP PTR TO NEXT CHAR, PUT 40 IN AC
	JMP QAJ		/34
	SHD I		/NEITHER
	4300
	JMP QAG		/CR. MOVE X AND Y COORDINATE
	JMP QAP		/ISPLAY CHAR
	JMP QAH		/PICK UP NEXT CHAR
	JMP QAP		/TO HERE IF DISPLAYING ANSWER BUFR
	SRO I	/SWITCH TO DISPLAY CURSOR. EITHER 0000 OR 7777
	0		/IFXR4=XR5, THEN SWITCH=7777
	JMP QAF
			/QUESTION MODE
QAI,	LDH I 5
	JMP QAO+1
	JMP QAH		/74
	JMP QAH		/34
	JMP QAI-4	/NEITHER. DISPLAY IT
QAJ,	JMP GETKBD	/TO HERE IF DISPLAYED BUFFER
	AZE I
	JMP QAB	/NOTHING TYPED . EXIT
	SET I 2
	QAY
	SHD 2		/LF?
	JMP QAK+4	/YES. EXIT
	SHD I 2		/CR?
	JMP QAN
	XSK 6		/IS THERE AN ANSWER FIELD?
	JMP QARFSH
	SHD I 2		/<?
	JMP QAL
	SHD I 2		/>?
	JMP QAK
	SHD I 2		/ALT?
	JMP QACA
	SHD I 2		/BACK SLASH?
	JMP QARFSH	/IGNORE
	SHD I 2		/RUBOUT?
	JMP QAL		/IGNORE
	SHD I 2		/TAB?
	JMP QARFSH	/IGNORE
	STC .+5		/ACCEPTABLE CHAR
	JMP QAO		/TEST NEXT CHAR
	JMP QAQ		/74 BACK PTR UP BY 1
	JMP QAQ		/34 ^
	LDA I		/OK. STORE IT
	0
	STH 4
	JMP QARFSH	/REDISPLAY
QAL,	LDH 4		/TO HERE IF RUBBOUT OR <
	JMP QAO+1
	JMP QARFSH	/74 IGNORE
	-6002
	LDH 2		/TEST THE CHAR
	SAE I		/RUBOUT?
	37
	JMP QAQ		/NO. BACK PTR UP BY 1
	SET 5
	4
	SET 3
	4
	JMP .+2
	LDH I 5		/BUMP PTR
	LDH I 3		/GET NEXT CHAR
	JMP QAO+1
	NOP		/IF 74 OR 34, REPLACE CURRENT CHAR WITH 0
	CLR
	STH 5
	AZE		/WAS IT 74 OR 34?
	JMP .-7		/NO. CONTINUE
	JMP QAQ		/BACK PTR UP BY 1
			/TO HERE IF CR
QAN,	XSK 6	
	JMP QAK+4	/EXIT ROUTINE IF NO ANSWER FIELD
	JMP QAO
	JMP QARFSH	/74 MOVE PTR TO NEXT QUESTION FIELD
	JMP QAE+1	/34 END OF BUFR. MOVE PTR TO FIRST QUESTION FIELD
	JMP QAN+2
	
QAO,	LDH I 4		/S\R
	SHD I		/	+1 74 BEGIN FIELD
	7400		/	+2 34 END BUFR
	JMP 0		/	+3 NEITHER 74 NOR 34
	SAE I
	34
	XSK I 0
	XSK I 0
	JMP 0
			/S\R TO DISP LINC CHAR IN AC
QAP,	ROL 1		/MULT BY 2 FOR INDEX TO ADDRESS OF TABLE
	ADD QAX+4
	STC 2		/ADDRESS OF CHAR TO DISP IN XR2
	ADD QAU		/THIS INSTR CHANGES. EITHER OP OR ADD 9U
	ADD QAU
	ADD 1		/ADD 4 TO XR1 TO SPACE CHAR
	STC 1
	ADD 5		/GET ADDRESS OF ANSWER BUFR
	COM
	ADD 4
	AZE
	CLR
	STC QAI-2	/SWITCH=0 OR 7777
	ADD QAH-1	/Y COORDINATE IN AC
	DSC 2
	DSC I 2		/DISPLAY CHAR
	JMP 0
QAQ,	LDA I		/BACK UP PTR BY 1
	-4000
	ADM
	4
	JMP QARFSH	/REDISPLAY
			/
QAT,	LDH I 1		/S\R
	SHD I		/	+1 F
	0600		/	+2 H
	JMP 0		/	+3 NEITHER
	SAE I
	10
	XSK I 0
	XSK I 0
	JMP 0
			/
QAZ,	LDH I 3
	LDA I
	40
	JMP QAI-4
			/TO HERE IF >
QAK,	LDH I 4
	AZE I		/IS CURRENT CHAR BLANK?
	JMP QAQ		/YES. IGNORE
	JMP QAX		/MOVE DOT FORWARD
			/TO HERE TO EXIT WITH SKIP
	LDA I
	1
	ADM
	QAB
	JMP QAB
			/CHARACTER PATTERNS
QAV,	0101		/KBD 0, ILLEGAL. USED AS MARKER
	0101
	4477		/1:A
	7744
	5177		/2:B
	2651
	4136		/3:C
	2241
	4177		/4:D
	3641
	4577		/5:E
	4145
	4477		/6:F
	4044
	4136		/7:G
	2645
	1077		/10:H
	7710
	7741		/11:I
	0041
	4142		/12:J
	4076
	1077		/13:K
	4324
	0177		/14:L
	0301
	3077		/15:M
	7730	
	3077		/16:N
	7706	
	4177		/17:O
	7741
	4477		/20:P
	3044
	4276		/21:Q
	0376
	4477		/22:R
	3146
	5121		/23:S
	4651
	4040		/24:T
	4077
	0177		/25:U
	7701	
	0176		/26:V
	7402
	0677		/27:W
	7701
	1463		/30:X
	6314
	0770		/31:Y
	7007
	4543		/32:Z
	6151
	4177		/33:/
	0000
			/34:BACKSLASH IGNORED ON INPUT
	0		/NOT USED
	0		/NOT USED
	0000		/35:]
	7741
			/CODES 36:ALT, 37:RUBOUT NOT DISPLAYED
QAY,	4543		/LF,CR
	7476		/<,>
	3634		/ALT, BACKSLASH
	3747		/RUBOUT, TAB
	0000		/40:SPACE
	0000
	7500		/41:X!
	0000
	7000		/42:"
	0070
			/CODES 43:, 44:, 45:LF NOT DISPLAYED
QAX,	JMP QAO+1
	JMP QAQ
	JMP QAQ
	JMP QARFSH
	QAV
	0		/NOT USED
	5166		/46: &
	0526
			/CODE 47:TAB NOT DISPLAYED
	0		/NOT USED
	0		/NOT USED
	3600		/50:(
	0041
	4100		/51:)
	0036
	2050		/52:*
	0050
	0404		/53:+
	0437
	0500		/54:,
	0006
	0404		/55:-
	0404
	0001		/56:.
	0000
	0601		/57:\
	4030
	4536	/60:0
	3651
	2101		/61:1
	0177
	4523		/62:2
	2151
	4122		/63:3
	2651
	2414		/64:4
	0477
	5172		/65:5
	0651
	1506		/66:6
	4225
	4443		/67:7
	6050
	5126	/70:8
	2651
	5122		/71:9
	3651
	2200		/72::
	0000
	4601		/73:;
	0000
			/CODE 74:<NOT DISPLAYED
QAU,	2		/CONSTANT
	0	/NOT USED
	1212		/75:=
	1212
			/CODE 76:> NOT DISPLAYED
QAW,	NOP
	ADD QAU
	4020		/77:?
	2055
/
QAF,	DSC I
	6000
	JMP QAI
/
			/END Q+A
/
/
/
/
/KEYBOARD INPUT ROUTINE
/
LKRB= 6036		/PDP-8 IOT KBD
LTSF= 6041		/TSF
LTLS= 6046		/TLS
/
GETKBD,	LDA
	0
	STC EXIT+6	/SAVE RETURN
	ADD 1		/SAVE XRS 1 AND 2
	STC EXIT+3
	ADD 2
	STC EXIT+5
	STC EXIT+1
	KST		/WAS SOMETHING TYPED?
	JMP 0		/NO: EXIT
	IOB
	LKRB		/GET TTY CHAR, CLEAR FLAG
	STA I		/SAVE IT
TY,	0
	ADA I
	-237
	APO		/BETWEEN 200 AND 237?
	JMP CNTRL	/CONTROL CHAR. CHECK FOR CR,LF, TAB
/
	SET I 1		/NO
	CHARS-1
	SET I 2
	-7
	LDA
	TY
	SAE I 1
	JMP .+2
	JMP EXIT	/ILLEGAL CHAR. DON	T ECHO
	XSK I 2		/CHECKED THEM ALL?
	JMP .-4
/
	ADA I
	-337
	APO		/BETWEEN 240 AND 337?
	JMP LEGAL	/YES. LEGAL CHAR
/
	SAE I 1		/NO. CHECK FURTHER.
	JMP .+7
	LDA I		/RUBOUT
	334
	JMP TPE		/ECHO BACKSLASH
	LDA I
	37
	JMP EXIT+2	/LEGAL EXIT
/
	SAE I 1
	JMP EXIT	/ILLEGAL
			/ALT
	JMP EXIT+2	/EXIT, DON	T ECHO
/
LEGAL,	LDA
	TY
	JMP TPE		/ECHO CHAR
	ADD TY
	BCL I		/STRIP IT TO 6-BIT
	7700
	JMP EXIT+2
/TO HERE IF CONTROL CHAR
CNTRL,	SAE I
	7755
	JMP CKLF
	LDA I		/CR
	43
	STC EXIT+1
	LDA I
	215
	JMP TPE
	LDA I
	212
	JMP TPE
	JMP EXIT
/
CKLF,	SAE I
	7752
	JMP .+4
	LDA I		/LF
	45
	JMP CNTRL+5
	SAE I
	7751
	JMP EXIT		/ILLEGAL
	LDA I
	47
	JMP EXIT+2	/EXIT, DON	T ECHO
/
EXIT,	LDA I		/GET 6-BIT ASCII
	0
	SET I 1		/RESTORE XRS
	0
	SET I 2
	0
	JMP		/EXIR S\R GETKBD
/S\R TO PRINT C(AC)
TPE,	IOB
	LTLS		/PRINT IT
	LDA
	0
	STC .+4		/SAVE RETURN
	IOB
	LTSF
	JMP .-2		/WAIT FOR FLAG
	JMP		/EXIT
CHARS,	243	/HASH
	244	/DOLLAR SIGN
	245	/PER CENT
	247	/APOSTROPHE
	300	/AT SIGN
	336	/UP ARROW
	337	/BACK ARROW
	40	/RUBOUT
	36	/ALT
/END OF S\R GETKBD
MONIT, SET I 15
	RCG
	SET I 16
	7300
	MSC I 1
	BCL I
	0010
	MSC 1
	JMP 15
/RETRIEVE BN
OVRTEX, LDH
	ANS3+4001
	AZE
	JMP LJUS1
	LDH	/NULL
	ANS3+1
	STH
	ANS3+4001
	LDH
	ANS3+4000
	STH
	ANS3+1
	LDA I
	0060
	STH
	ANS3+4000
LJUS, LDH
	ANS3+4001
	AZE
	JMP LJUS1
	LDH		/NULL
	ANS3+1
	BSE I
	6000
	STA
	ANS3+1
LJUS1, LDH
	ANS3+4000
	BCL I
	0070
	ROL 6
	BSE I
	5000
	STA
	BN
	LDH
	ANS3+1 /LEFT HALF INTO RT ACC
	BCL I
	0070
	ROL 3
	ADM
	BN
	LDH
	ANS3+4001 /RT HALF TO RT ACC
	BCL I
	0070
	ADM
	BN	/BN=5XXX
	LDF 1
	STA
	2037 /BN
	ADA I
	1001	/BN=5XXX+1
	BCL I 	/PREVENTS QTR 7 IF
	1000	/BN REQUESTED=777
	STA
	BN1	/BN1=6XXX+1
/RETRIEVE UNIT FROM QASUB
	LDH
	ANS3+4002
	BSE I
	4000
	STA
	2005 /UNCODE+4002
	BCL I
	4076
	ROL 3
	ADA I
	RDE	/UNIT LEAST BIT SET
	STA
	RDTP1	/INIT READ, Q5
	STA
	RDTP2	/INIT READ, Q6
	STA
	2006 /RDTP3
	STA
	2007 /RDTP4
	LDH
	ANS3+4002
	BCL I	/EXT TAPE UNIT BITS
	0071
	ROR 1
	BSE I
	0010
	STA
SETUN
	MSC I 1 /0021
	BSE I
SETUN, 0
	MSC 1 /0001
	LDF 3
RDTP1,	0	/RDE U
BN,	0	/5XXX, WHEN X=BN
	STD
	JMP .-1	/TAPE BUSY
RDTP2,	0	/ROE U
BN1,	0	/6XXX, WHERE X=BN+1
	STD
	JMP .-1	/TAPE BUSY
	LIF 1
	JMP 20
SEGMNT 1
*20
	LDA
5
STA
UNCODE+4002
LDA
6
STA
RDTP3
LDA
7
STA
RDTP4
/IX10:	DISPLAY COUNTER
/IX11:	CURRENT CORE POSITION
/IX12:	INITIAL CORE POSITION
/IX13:	INITIAL QNBN
/IX14:	CURRENT QNBN
/IX15:  CURRENT ASCII H\W COUNTER
PART2,	SET I 12	/INIT CORE POSN
	2400
	SET I 13
	0	/BN TRF FROM BANK2
/INITIALIZE DISPLAY LOOP
DSLOOP, SET 11/RESET CURRENT CORE
	12
	SET 14	/RESET CURRENT QNBN
	13
	SET I 10
	0777
	LDA
	12
	ADA I
	-1
	STA
	15
/DISPLAY LOOP
DSNORM, SNS 0
	JMP ASCII
	LDA 11
	DIS I 10
/CHECK FOR END OF QTR
	LDA
	11
	BSE I
	7400
	AZE I	/377 CHECK
	JMP EOQTR	/YES, END OF QTR
/LOOP UPDATE
QTRRET,	XSK I 11
	NOP
	XSK 10	/MORE PTS TO DISPLAY
	JMP DSNORM	/YES
/DISPLAY TERMINAL:
/DISPLAY UNIT.
/SAMPLE.
/READ IN NEW BLOCK, IF NECESSARY.
/IF NEW INIT CODE ROLLS OVER INTO
/DIFFERENT QTR, UPDATE INIT. BN+QTR.
	JMP UNTILE	/DISPLAY UNIT NUMBER
SAM7, SAM 7
	COM
	SCR 6
	STA I
SAMPLE,	0
	APO	/DIR OF TAPE MTN
	JMP DNTP	/NEG - DN
	JMP UPTP	/POS - UP
/DISPLAY BN DIVIDER
EOQTR,	XSK 10	/END OF SCOPE
	JMP .+2	/NO
	JMP NEXT	/YES
	XSK I 10	/UPDATE SCOPE CT
	NOP
	SET I 2
	-100
	LDA I
	7400
MORPT,	DIS 10
	ADA I
	6
	XSK I 2
	JMP MORPT
/DISPLAY BLOCK NUMBER
NEXT,	LDA
	10
	ADA I
	-1200
	APO	/ROOM FOR BN
	JMP UP14	/NO ROOM
	STA
	1	/H COORD SET
MIDEOQ, LDH /QXVZ
	14	/00QX
	BCL I
	7770
	BSE I
	0060
	STH
	BNCODE+4001
	LDH
	14+4000	/00YZ
	ROR 3	/Z00Y
	BSE I
	0060
	STH
	BNCODE+2
	LDH
	14+4000	/00YZ
	BCL I
	7770	/0002
	BSE I
	0060
	STH
	BNCODE+4002
	SET I 2
	-6
	SET I 3
	BNCODE-1+4000
GOGO,	LDH I 3
	ROL 1
	ADA I
	A9V
	STC 4
	LDA I
	0300
	DSC 4
	DSC I 4
	LDA I
	4
	ADM
	1
	XSK I 2
	JMP GOGO
/UPDATE QNBN
UP14,	LDA
	14
	BCL I	/PREVENTS 7777 CASE
	7000
	ADA I
	1
	BCL I	/PREVENTS X777 ROLLOVER
	7000
	STA I
STORE,	0
	LDA
	14
	BCL I
	0777
	ADA I
	1000
	BSE I
	4000
	BCL I
	0777
	ADA
	STORE
	STC 14	/IX14 NOW UPDATED
	JMP QTRRET
BNCODE,	0216
	4000
	0000	/Y,Z
UNCODE,	2516
	1124
	4000
UNTILE,	SET I 2
	-6
	SET I 3
	UNCODE-1+4000
	SET I 1
	4
GOGOO,	LDH I 3
	ROL 1
	ADA I
	A9V
	STC 4
	LDA I
	0340
	DSC 4
	DSC I 4
	LDA I
	4
	ADM
	1
	XSK I 2
	JMP GOGOO
	JMP SAM7
UPTP,	LDA
	14
	BCL I
	7000	/PREVENTS 7777 CASE
	ADA I
	1
	BCL I
	7000	/PREV