*20
	PMODE
	*20
SH1,	0
SH2,	0
SH3,	0
SHUFEL,	SHUFL
RNX,	RN
IRX,	IR
K7,	7
TEMP,	0
R1,	0
R2,	0
R3,	0
INDEX6,	0
RNDM3,	0
RNDM2,	0
RNDM1,	RNDM
RMNDR,	RMNDRX
TICKS,	0
ROWS,	0
WORDS,	0
LETTER,	0
M144,	-144
Y0,	360		/INIT. V.C.
DY,	-240		/PTS TWEEN ROWS
X0,	774		/INIT H.C.-4
DX,	74		/PTS TWEEN T&H
M4,	-4
M5,	-5
M6,	-6
Y,	0
POINTR,	0
C3777,	3777
LISTS,	0
TIME,	-50		/-SECS DISPLAY
CLOCK,	5100		/HSEC CLOCK
D300,	454
COUNT,	0
NLIST,	-17		/-NO. LISTS/SUB.
TIPE,	TYPE
PWTABL,	PATRN-2
C212,	212
C215,	215
C240,	240
C300,	300
M10,	-10
C170,	170
/OUTPUT SUBR
TYPE,	0
	TLS
	TSF
	JMP .-1
	CLA
	JMP I TYPE
/PROGRAM STARTS HERE: READ IN 300 
/6-LETTER WORDS INTO 4000-7407
START,	CLA
	LINC
	LMODE
	ESF		/SET HALF-SIZE
	LDF 2
	RDC U
	4760
	RDC U
	5761
	RDC U
	6762
	RDC U
	7763
	LDF 3
	RDC U
	4764
	RDC U
	5765
	RDC U
	6766
	RDC U
	7767
	PDP
	PMODE
	ISZ COUNT	/INIT R.N.
	NOP
	LAS
	SZA CLA
	JMP .-4
	JMS I IRX
	JMS I RNX
	ISZ COUNT
	JMP .-2
/EXPERIMENT BEGINS HERE
BEGIN,	CLA
	TAD M6
	DCA SH3
	TAD D300
	DCA SH2
	TAD C3777
	DCA SH1		/SHUFFLE WORDS
	JMS I SHUFEL
	CLA
	TAD NLIST
	DCA LISTS	/ISZ ON LISTS
	TAD C3777
/EACH TRIAL BEGINS HERE
/PRINT OUT ARRAY OF NEXT LIST TO BE
/DISPLAYED TO FACILITATE SCORING RECALL
TRIAL,	DCA POINTR
	TAD POINTR
	DCA 10
	TAD M4
	DCA ROWS	/DO 4 ROWS
PROW,	TAD M5
	DCA WORDS	/5 WORDS/ROW
	TAD C215
	JMS I TIPE
	TAD C212
	JMS I TIPE
	TAD C212
	JMS I TIPE	/CR,LF,LF
PWORD,	TAD M5
	DCA 1
	TAD C240
	JMS I TIPE	/5 BLANKS TWEEN
	ISZ 1		/WORDS
	JMP .-3
	TAD M6
	DCA LETTER	/6 LETTERS/WD
	TAD I 10
	TAD C300
	JMS I TIPE
	ISZ LETTER
	JMP .-4
	ISZ WORDS
	JMP PWORD
	ISZ ROWS
	JMP PROW
	TAD M10
	DCA 1
	TAD C215
	JMS I TIPE
	TAD C212
	JMS I TIPE	/CR,10 LFS
	ISZ 1
	JMP .-3
/WORD ARRAY TO BE DISPLAYED NOW PRINTED
/AND EJECTED: WAIT FOR CONSOLE RESTART
/BEFORE BEGINNING DISPLAY
	HLT
	TAD TIME	/-SECS OF DISPLA
	DCA TICKS	/"TICK"=1 SEC.
	CLLR
	TAD M144	/100 BEATS/TICK
	CLAB
	CLA
	TAD CLOCK	/HSEC. BEATS
	CLLR
	CLSA		/CLEAR FLAG
	CLA
DISP,	TAD POINTR
	DCA 10		/AD-1 LIST
	TAD M4
	DCA ROWS
	TAD Y0
ROW,	DCA Y		/SET V.C.
	TAD M5
	DCA WORDS	/5 WORDS/ROW
	TAD X0
WORD,	DCA 1		/SET H.C.
	TAD M6
	DCA LETTER	/6 LETTERS/WD
LETTR,	TAD I 10	/NEXT CHAR
	CLL RAL
	TAD PWTABL
	DCA 2		/AD P.W.
	TAD Y		/CURRENT V.C.
	LINC
	LMODE
	DSC 2
	DSC I 2		/DISPLAY LETTER
	PDP
	PMODE
	CLA
	ISZ 1		/1 PT. TWEEN LET
	ISZ LETTER	/ANOTHER LETTER?
	JMP LETTR
	ISZ WORDS	/DONE W/ROW?
	SKP
	JMP ENDROW
	TAD DX		/NO. PTS. TWEEN
	TAD 1		/TAIL-LEAD WDS
	JMP WORD
ENDROW,	ISZ ROWS	/ANOTHER ROW?
	SKP
	JMP ENDISP
	TAD Y
	TAD DY		/V.C. NEXT ROW
	JMP ROW
ENDISP,	CLSA		/CLOCK STATUS
	SMA CLA		/OVERFLOW=TICK?
	JMP DISP
	ISZ TICKS	/ENOUGH TICKS?
	JMP DISP
	HLT		/DONE WITH DISPL
	ISZ LISTS	/ANOTHER LIST?
	SKP
	JMP I IBEGIN	/NEXT SUBJECT
	TAD POINTR
	TAD C170	/AD NEXT LIST
	JMP I ITRIAL	/NEXT TRIAL
ITRIAL,	TRIAL
IBEGIN,	BEGIN
/RANDOM PACKAGE BEGINS HERE
	PAGE
RNDM,	0		/RN IN 0,RNDM3
	JMS I RNX	/36 BIT RN
	JMS I RMNDR	/REMAINDR RNDM3
	CLA
	JMP I RNDM	/DONE
M36,	-44		/
IDX1,	0		/
R1X,	0		/
R2X,	0		/
R3X,	0		/
RMNDRX,	0		/GET RMNDR
	CLA		/
	DCA RNDM2	/
	TAD R1		/
	DCA R1X		/
	TAD R2		/
	DCA R2X		/
	TAD R3		/
	DCA R3X		/
	TAD M36		/
	DCA IDX1	/FOR 36 BITS
RMN1,	CLA		/
	TAD RNDM2	/
	CLL		/
	RAL		/
	DCA RNDM2	/SHIFT LEFT 1
	TAD R1X		/
	CLL		/
	RAL		/
	DCA R1X		/SHIFT LEFT 1
	RAL		/GET LINK
	TAD RNDM2	/
	DCA RNDM2	/
	TAD R2X		/
	CLL		/
	RAL		/
	DCA R2X		/
	RAL		/GET LINK
	TAD R1X		/
	DCA R1X		/
	TAD R3X		/
	CLL		/
	RAL		/
	DCA R3X		/
	RAL		/GET LINK
	TAD R2X		/
	DCA R2X		/SHIFTS DONE
	TAD RNDM3	/NUMBER MOD
	CIA		/
	TAD RNDM2	/
	SPA		/
	JMP .+2		/
	DCA RNDM2	/SUB,REPLACE
	ISZ IDX1	/CHECK INDEX
	JMP RMN1	/CONTINUE
	JMP I RMNDRX	/RMNDR IN RNDM2
SHUFL,	0		/SHUFFLES
SHUFL1,	CLA		/
	TAD SH2		/LENGTH
	DCA RNDM3	/
	JMS I RNDM1	/GET RN
	CLA		/
	TAD SH3		/BLOCK SIZE
	DCA INDEX6	/
	TAD SH1		/ARRY-1
SHUF1,	TAD RNDM2	/ADD TO ARRY
	ISZ INDEX6	/N X M DONE?
	JMP SHUF1	/CONTINUE
	DCA TEMP	/DONE,IN TEMP
	TAD TEMP	/
	DCA 14		/
	TAD TEMP	/
	DCA 15		/
	TAD SH1		/
	DCA 16		/
	TAD SH1		/
	DCA 17		/
	TAD SH3		/
	DCA INDEX6	/-BLOCK SIZE
SHUF2,	TAD I 14	/
	DCA TEMP	/
	TAD I 16	/
	DCA I 15	/
	TAD TEMP	/
	DCA I 17	/
	ISZ INDEX6	/
	JMP SHUF2	/
	CLA CMA		/AC=-1
	TAD SH2		/LENGTH-1
	SZA		/
	JMP .+2		/
	JMP I SHUFL	/DONE
	DCA SH2		/NEW LENGTH
	TAD SH3		/BLOCK SIZE,-
	CIA		/+BLOCK SIZE
	TAD SH1		/ADD ARRAY
	DCA SH1		/NEW START
	JMP SHUFL1	/CONTINUE
	PAGE
IR,	0		/
	JMP IR1		/
RN,	0		/
	CLA		/
	TAD R3		/
	RAL		/
	AND K7400	/
	DCA T3		/
	TAD R2		/
	AND K177	/
	TAD T3		/
	RTL		/
	RTL		/
	RAL		/
	DCA T1		/
	TAD R3		/
	AND K177	/
	RTL		/
	RTL		/
	RAL		/
	TAD R2		/
	DCA T2		/
	SZL		/
	ISZ T1		/
	NOP		/
	TAD R3		/
	CLL RAL		/
	SZL		/
	ISZ T2		/
	SKP		/
	ISZ T1		/
	NOP		/
	CLL		/
	TAD R3		/
	DCA R3		/
	TAD R2		/
	RAL		/
	SZL		/
	ISZ T1		/
	NOP		/
	CLL		/
	TAD T2		/
	DCA R2		/
	TAD R1		/
	RAL		/
	TAD R1		/
	TAD T1		/
	DCA R1		/
	TAD R1		/
	JMP I RN	/
	HLT		/NOT USED
IR1,	CLA IAC		/
	DCA R3		/
	DCA R2		/
	DCA R1		/
	JMP I IR	/
K177,	177		/
K7400,	7400		/
T1,	0		/
T2,	0		/
T3,	0		/
/PATTERN WORDS FOR CHAR DISPLAY
PATRN,	4477		/A
	7744
	5177		/B
	2651
	4136		/C
	2241
	4177		/D
	3641
	4577		/E
	4145
	4477		/F
	4044
	4136		/G
	2645
	1077		/H
	7710
	7741		/I
	0041
	4142		/J
	4076
	1077		/K
	4324
	177		/L
	301
	3077		/M
	7730
	3077		/N
	7706
	4177		/O
	7741
	4477		/P
	3044
	4276		/Q
	376
	4477		/R
	3146
	5121		/S
	4651
	4040		/T
	4077
	177		/U
	7701
	176		/V
	7402
	677		/W
	7701
	1463		/X
	6314
	770		/Y
	7007
	4543		/Z
	6151
	4177		/[
	0000
	2040		/\
	0410
	0		/]
	7741
	2000		/^
	2077
	3410		/BACK ARROW
	1010
	0		/SPACE
	0
	7500		/!
	0
	6006		/"
	60
	3614		/NUMBER SIGN
	1436
	7721		/DOLLAR SIGN
	4677
	1446		/%
	6130
	5166		/&
	0523
	500		/APOSTROPHY
	
	6
	4163		/(
	0
	0		/)
	6341
	2050		/*
	50
	404		/+
	437
	605		/,
	0
	404		/-
	404
	1		/.
	0
	601		//
	4030
	4136		/0
	3641
	2101		/1
	177
	4523		/2
	2151
	4122		/3
	2651
	2414		/4
	477
	5172		/5
	651
	1506		/6
	4225
	4443		/7
	6050
	5126		/8
	2651
	5120		/9
	3651
	4200		/:
	0
	2601		/;
	0
	2410		/<
	0042
	1212		/=
	1212
	4200		/>
	1024
	4020		/?