Directory of image this file is from
This file as a plain text file

*20
//TTEST CODING.
/A USEFUL SUBROUTINE TO CREATE T
/VALUE FROM 2 SETS OF MEANS WITH
/THEIR STD DEVIATIONS.
/COMES FROM PROGRAM SYSTTST.
/HAVE TWO DATA SETS
/COMPUTE T
/
G2,	LDF 16
	SFLOAT
	P20
	STORE
	N1		/NUM ENTRIES IN ENSMBL 1
	LDF 17
	SFLOAT
	P20
	STORE
	N2		/NUM ENTRIES IN ENSMBL 2
	 
	LDA
	P17
	COM
	STC NSAM	/DATA PTS AS CNTR
	 
	 
	SET I 7		/CNTR
NSAM,	0
/
	SET I 12
	2000		/PNTR TO DATA
	SET I 13
	3000		/PNTR TO STD DEV
	 
	 
NXTPT,	LDF 6
	SFLOAT
	12
	LDF 16
	NORM
	STORE
	M1 		/MEAN 1
	 
	LDF 6
	SFLOAT
	13
	LDF 16
	NORM
	STORE
	S1		/SD1
	 
	LDF 7
	SFLOAT
	12
	LDF 17
	NORM
	STORE
	M2 		/MEAN 2
	 
	LDF 7
	SFLOAT
	4\13		/ALSO BUMP 13
	LDF 17
	NORM
	STORE
	S2		/SD2
	 
	JMP GETT	/RTRN WITH T IN FAC
	 
	JMP CHOP	/HANDLE ODD CASES
	 
/STORE T IN DF10, PBLOCK IN QN7, DF20.
	FIXFAC
	LDF 10
	ISTOR1	
	4\12		/STORE T & BUMP 12
	 
/RECYCLE IF MORE POINTS NEED TO BE PROCESSED.
	XSK I 7
	JMP NXTPT
	 
/DUN ALL POINTS SO SETUP PBLOCK.
	SET I 2		/CLEAR PBLOCK AREA
	3377
	CLR
	LDF 20
	STA I 2
	XSK 2
	JMP .-2
	 
	LOAD
	ADSCL
	FDIV
	FP25	        /OCTAL SCALING
	FDIV
	FP25	        /P43
	STORE
	P42		/MULFAC
	LOAD
	FP25	        /MAX VERT IN VIEW
	STORE
	P43		/UV\V
	ADD NSAM
	COM
	STA
	P17		/SAM\SEG
	LOAD
	N1
	FADD
	N2
	FSUB
	FONE
	FIXFAC
	ISTOR1
	P20		/SEG OF FREEDOM
	LDF 17
	LDA
	P0		/DATA TYPE
	BSE I
	60
	LDF 20
	STA
	P0
	LDF 17
	LOAD
	P44		/SEG LENGTH
	LDF 20
	STORE
	P44
/ALL DUN WITH CALCULATION, APPEND STORAGE.
	 
	 
	 
/COMPUTE T VALUE.
/
GETT,	SET 17
	0
/M1-M2
	LOAD
	M1		/ENSMBL 1 MEAN
	FSUB
	M2		/MEAN 2
/
/ABS VALUE
/
	FAPO
	FCOMP
	STORE
	M1
/
	RECIP
	N1
	STORE
	TEM
	RECIP
	N2
	FADD
	TEM
	STORE
	TEM 		/1\N1 + 1\N2
/
/N1+N2-2=TEM1
/
	LOAD
	N1
	FADD
	N2
	FSUB
	FTWO
	STORE
	TEM1 		/N1+N2-2
/
/TEM2= NX SX SQ + TEM2
/
	LOAD
	S1
	SQUARE
	FMUL
	N1
	STORE
	TEM2
	LOAD
	S2
	SQUARE
	FMUL
	N2
	FADD
	TEM2
	FAZE
	JMP .+2
	JMP SETT	/ARBITRARY SET
/
	FDIV
	TEM1
/
	FMUL
	TEM
/
	SQRT
	FAC
/
	STORE
	TEM2
	LOAD
	M1
	FDIV
	TEM2
/T IS IN FAC
/
	JMP 17		/LEAVE GETT
/END GETT.
	 
	 
/ROUTINE TO SQUARE OFF F OR T VALUES
/AT 25.
CHOP,	SET 17
	0
	STORE
	TEM
	FSUB
	FP25
	FAPO
	JMP .+4
	LOAD
	FP25
	JMP .+3
	LOAD
	TEM
	FMUL
	FP25
	JMP 17		/LEAVE
/END CHOP.
	 
/ROUTINE TO SET T TO ARBITRARY VALUES
/IN CASE WHERE S1 & S2 =0.
/IF ABS(M1-M2) =0,WITHIN +\- 2BITS,
/SET T=0.  
/IF ABS(M1-M2) > 0, WITHIN +\- 2 BITS, 
/SET T=-1. (IN THIS CASE T IS ACTUALLY
/INFINITE).
SETT,	LDF 6
	LDA 12
	COM
	STC TEM
	LDF 7
	LDA 12
	ADD TEM
	SCR 2
	AZE
	JMP .+3
	FZER
	JMP 17		/LEAVE, T=0
	SFLOAT
	KM1
	JMP 17		/LEAVE, T=1
/END SETT.
//END TTEST CODING.