Directory of image this file is from
This file as a plain text file

*20
	/// VIEW
/THE PROGRAM TO
/DISPLAY STORED DATA
/ON THE PDP-12 SCOPE
/LODSYM NOT NEEDED. PBLOCK ADDED.
/BLOCKS 40-43
/SUPPORT 44
/PRINT 45,46
/
	STD=416
	SEGMNT 5
	*20
/GET SUPPORT
	LDF 7
	IOB 12
	4044
/
/START CURSOR TESTER
	IOB 1
TWO,	2
	SAMT
	JMP .-3
/GET NEXT DATUM FOR DISPLAY
/
	JMP GETINT
LSCN,	JMP GETONE
	JMP .-2
	JMP SCREEN 	/SET UP DISPLAY
/
/SEND MESSAGE AND OPEN
/INPUT BUFFER
LISN,	LDA
	CURTMP
	STC CURFLG
	STC OCR
/
	IOB 11
	7704
	-1
	5
	272
	JMP .-5
/
	IOB 11
	0113
	215
	4
	INBUF
	JMP .-5
/
	IOB 1
	13
	DECODE
	JMP .-3
	IOB 5
	EJECT
/TEST FOR CURSOR
/
SAMT,	IOB 7
	SAM 3
	SCR 1
	STC SDY
/
	COM
	SNS 2
	ADD DT10+3
	STC STBUF
/
	ADD ONE
	SNS I 3
	ADD ONE
	STC DT1
/
	CLR
	SNS I 1
	COM
	SAE I
DXW,	7777
	JMP CDX
/
NDX,	LDA
	CURFLG
	APO I
	JMP SAMT
/
/MUST STAY AWAKE
/
SAMC,	SAM 7
	ADA I
	1004
	SCR 2
	STA
	DT8A
	STA
	DT3
/
/TEST FOR NEW CONVERSION
	SAE I
OCR,	0
	SKP
	JMP SAMT
	STC OCR
	JMP GETCP 	/GET CURSOR POINT
/
/OUTPUT TO BUFFER
	SETWRD
	742
	OUTPUT
	4\CXB+1		/X
	LOAD
	TEM1
	OUTPUT
	4\CYB+1		/Y
	SQRT
	TEM3
	ADD VFLG
	AZE I
	FZER
	OUTPUT
	4\CSB+1		/SD
/
	JMP SAMT
/
/ENABLE THE DISPLAY
/
CDX,	STA
	DXW
	APO
	JMP .+4
	LDA I
	DISBUF
	JMP .+3
	LDA I
	DATS
	STA
	PL 	/PLOT BUFFER
	STC DL 	/DISPLAY BUFFER
/
	IOB 2
	26
	IOB 11
	26
	0
	5
DL,	DISBUF
	JMP .-5
/
	JMP NDX
	EJECT
/THE KEY HANDLER
/
/COME HERE WHEN INPUT BUFFER COMPLETE
/
DECODE,	LDA I
CURFLG,	0
	STC CURTMP
	STC CURFLG
	LDA I
	I2-1
	LIF 4
	STRSCN
/LEVEL 1
	JMP L1
/LEGAL
	JMP LEGAL
/ILLEGAL
	JMP LISN
/UNKNOWN
	JMP LISN
/CR
	LIF 7
	JMP OPTTST
/
L1,	SAE I
	GET
	JMP LISN
	JMP LSCN+2 	/RESET SCREEN
/
LEGAL,	SHD I
	2000
	JMP DONO
	SHD I
	2400
	JMP LSCN 	/NEXT
	SHD I
	2500
	JMP DOCURS
	SHD I
	4400
	JMP DOTABL
	SHD I
	4300
	JMP DOPLOT
/
/PERHAPS A KEY VALUE
/
	ADA I
	-30
	MUL I
	14
	ADA I
	P104-14
	JMP DOKEY
	EJECT
/LEGAL COMMAND LIST
I2,	NO
	PRINT
	NEXT
	CURSOR
	PLOT
	A
	B
	C
	D
	E
	F
	G
	H
	II
	J
	EJECT
/COMMAND HANDLERS
DOPLOT,	IOB 2
	30
	IOB 11
	30
	0
	5
PL,	DISBUF
	JMP .-5
	JMP LISN
/
DONO,	CLR
	STC CURTMP
	STC DT3
	STC DT8A
	SET I 5
	CXB
	JMP CLB
	SET I 5
	CYB
	JMP CLB
	SET I 5
	CSB
	JMP CLB
	JMP LISN
/
CLB,	SET 6
	0
	SET I 7
	-4
	LDA I
	4040
	STA I 5
	XSK I 7
	JMP .-2
	JMP 6
/
DOCURS,	CLR
	COM
	STC CURTMP
	JMP LISN
/
DOTABL,	IOB 12
	1045
	JMP 400
/
	IOB 12
	1041
	JMP LISN
	EJECT
/CHECK FOR KEY VALUE
/LEGALITY
DOKEY,	STC PWORD
	LDA I
CURTMP,	0
	APO I
	JMP KEYTYP
	LDF 7
	LDA
	P0
/TEST FOR PERID
	BCL I
	7477
	AZE
	JMP LISN
/
	LDA
	P0
	ROR 1
	APO I
/TEST FOR FOURIER
	JMP CD
	LDA
	PWORD
	COM
	ADA I
	P130
	APO I
	JMP LISN 	/NOT E-J
	EJECT
/KEY VALUE MODIFICATION
/
CD,	LDA I
PWORD,	0
	STA
	6
	ADA I
	6
	STC 7
	LDF 7
	LOAD
	TEM2
/CHECK OPTIONS
	LIF 7
	LSW
	ROL 3
	APO
	JMP KINTR
	ROL 1
	APO
	JMP KAVG
	ROL 1
	APO
	JMP KVRMS
	ROL 2
	APO
	JMP KIGNOR
	ROL 1
	APO
	JMP KINSRT
	ROL 2
	APO
	JMP SCALAV
	LIF 5
	EJECT
/STORE AND PRINT
/KEY VALUES
	LSW
	APO I
	JMP KA-1
	FSUB
	6
	STORE
KA,	4\6 	/X
	LOAD
	TEM1
	LSW
	APO I
	JMP .+3
	FSUB
	7
	STORE
	4\7 	/Y
/
/GET VARIANCE
/
	ADD VFLG
	AZE I
	JMP KPT
	FZER
	STORE
	6
/VERT
	LOAD
	TEM3
	STORE
	7
KPT,	SNS I 4
	JMP LISN
	EJECT
KEYTYP,	LDF 7
	SET 6
	PWORD
	LDA 6
	SAE I
	3777
	SKP
	JMP LISN 	/NULL VALUE
/
	SETWRD
	1243
	LOAD
	4\6 	/X
	JMP KEYOUT
	LOAD
	4\6
	LOAD
	4\6 	/Y
	JMP KEYOUT
/
	LDA I
VFLG,	0
	AZE I
	JMP LISN
/TYPE S.D.
	SQRT
	6 	/SD
	JMP KEYOUT
	JMP LISN
	EJECT
KEYOUT,	SET 16
	0
	OUTPUT
	KEYBUF
/
	IOB 11
	4104
	212
	5
	KEYBUF
	JMP .-5
	IOB 1
	4
	.+3
	JMP .-3
	IOB 5
	JMP 16
	EJECT
/DATA SCAN
/
/CODE TO SCAN SEQUENTIALLY
/OR FROM A TABLE
/
/FOUND IN ALL THE SCAN ROUTINES
/
GETINT,	SET 3
	0
	LIF 4
	GETINI
	LDF 4
	LDA I
W1,	7107 	/PBLOCK LOCATION
	STA
	WORD1
	LDA I
W2,	4406 	/DATA LOCATION
	STA
	WORD2
	CLR
	JMP 3
/
/GET NEXT LOGICAL TAPE BLOCK
/
GETONE,	SET 3
	0
	LIF 4
	GETNXT
	JMP 3 	/NO MORE DATA
/
/GOOD DATUM , GET IT
/
GETIT,	LIF 4
	GETFST
	JMP 3
	XSK I 3
	JMP 3
	EJECT
/THE CODE WHICH SETS
/UP A DISPLAY
/
SCREEN,	LDA
	0
	STC SCRENX
/
	JMP DNAM 	/SET UP NAME
	JMP DTIC 	/SET UP SCALE
	JMP DSD 	/SET UP SD IF POSSIBLE
	JMP DDAT 	/SET UP DATA
/
SCRENX,	JMP
	EJECT
/SET UP NAME,TYPE,N,VRMS
/
DNAM,	LDA
	0
	STC DNAMX
	LDF 4
	LDA
	FILNAM
	STC NAMBUF+1
	LDA
	FILNAM+1
	STC TEM
	STC TEM+1
	SETWRD
	400
	DFLOAT
	TEM
	OUTPUT
	NAMBUF+2
	LDF 7
	SFLOAT
	P0 	/TYPE
	OUTPUT
	DATTYP+1
	SFLOAT
	P20
	OUTPUT
	4\NBUF+1
	SFLOAT
	P17
	OUTPUT
	4\PBUF+1
/
	SETWRD
	742
	LOAD
	P102 	/VRMS
	OUTPUT
	4\RMSBUF+1
/
DNAMX,	JMP
	EJECT
/CODE TO SET UP SD
/
DSD,	LDA
	0
	STC DSDX
/
	LDF 7
	LDA
	P0
	BCL I
	7737
	AZE I
	JMP NOSD 	/NOT HERE
/
	STC VFLG
	ADD TOTP 	/ POINTS
	COM
	STC 7
	SET I 4
	3000
	SET I 6
	2777
/
GSD,	LDF 6
	LDA 4
	LDF 7
	STA I 6
	LDA
	PSKP
	ADD 4
	STC 4
	XSK I 7
	JMP GSD
	SKP
NOSD,	STC VFLG
DSDX,	JMP
	EJECT
/CODE TO PERFORM BASELINE RESET
/
BASET,	LDA
	CURTMP
	APO I
	JMP LISN
	JMP GETCP
	LDA
	P17
	COM
	STC 7
	LDF 6
	ADD RW
	STC 5
	LDA 5
	COM
	STC DTICX
/
	SET I 5
	3777
	LDA I 5
	ADD DTICX
	STA 5
	XSK I 7
	JMP .-4
	JMP LSCN+2 	/RESET SCREEN
	EJECT
/CODE TO SET UP SCALE
/
DTIC,	LDA
	0
	STC DTICX
/
	LDF 7
	SFLOAT
	P17 	/ SAMPLES
	FDIV
	XSCL
	FADD
	FONE
	FIX
	FAC
	ISTOR1
	PSKP
/
	SFLOAT
	PSKP
	STORE
	TEM
	SFLOAT
	P17
	FDIV
	TEM
	FIX
	FAC
	ISTOR1
	TOTP 	/POINTS IN DISPLAY
	EJECT
/MOVE DATA TO BANK 7
/
	SET I 5
DST,	2000
	SET I 6
	2377
/
	SFLOAT
	TOTP
	STORE
	TEM1
	LOAD
	VSCL
	FDIV
	TEM1
	FIX
	FAC
	ISTOR1
	DT6 	/SCOPE SPACING
	ISTOR1
	DT10 	/SD SPACIG
	LDA I
TOTP,	0
	ADD MONE
	MUL
	DT6
	STA I
XDR,	0
	ADD C140
	STA
	Y1+1 	/ABSBUF
	STC DX1 	/LABLE
	SFLOAT
	XDR
	FDIV
	FTEN
	FIX
	FAC
	ISTOR1
	DVX
	ADD DVX
	ADD DVL
	STC DVX
/
TN,	ADD TOTP
	STA
	DT2 	/DATA SIZE
	STA
	DT8 	/SD SIZE
	COM
	STC 7
/
TICNB,	LDF 6
	LDA 5
	LDF 7
	STA I 6
/
	LDA
	PSKP
	ADD 5
	STC 5
	XSK I 7
	JMP TICNB
	EJECT
/DATA IS NOW IN BANK 7
/GET SCALE FACTOR
/
GF,	JMP FUDGE
/
/COMPUTE BUFFER LENGH IN
/HZ OR MSEC
/
/FIRST FIND OUT WHAT ONE
/ONE POINT IS WORTH
/
	SETWRD
	641
	LDA
	P0
	ROL 1
	APO
	JMP EG1 	/STAT DATA
	ROR 2
	APO
	JMP FR1 	/FOURIER DATA
	EJECT
/EEG DATA
/
EG1,	SFLOAT
	P17
	FSUB
	FONE
	STORE
	TEM1
	LOAD
	P44 	/ SECONDS
	FMUL
	THOU
	FDIV
	TEM1
/SECONDS PER POINT
	STORE
	MSEC 	/SECONDS PER POINT
	LOAD
	P44
/
/GOT SECONDS AT ENT
/OF BUFFER
/
	FMUL
	THOU
	OUTPUT
	4\ABSBUF
/
/
	LOAD
	P46
	FMUL
	THOU
	STORE
	BDLY 	/BASELINE DELAY
/
	SETWRD
	1042
	LOAD
	SCLFAC
	OUTPUT
	ORDBUH+1
	FCOMP
	OUTPUT
	ORDBUL+1
	LDA I
	-352
	STC Y3
	JMP DTICX
	EJECT
/FOURIER DATA
/
FR1,	RECIP
	P44
	STORE
	MSEC 	/HZ PER POINT
	SFLOAT
	P17
	FMUL
	MSEC
	FSUB
	MSEC
	OUTPUT
	4\ABSBUF 	/LAST HZ
/
	SETWRD
	1042
	LOAD
	SCLFAC
	OUTPUT
	ORDBUH+1
	LDA I
	4040
	STA
	ORDBUL+1
	STA
	ORDBUL+2
	STA
	ORDBUL+3
	STC ORDBUL+4
	LDA I
	-42
	STC Y3
DTICX,	JMP
	EJECT
FUDGE,	LDA
	0
	STC FUDGX
	LDF 7
	LOAD
	P43 	/MICROVOLTS
	STORE
	SCLFAC
/
	SNS I 0
	JMP GETFIX
F1,	SNS I 5
	JMP GETINS
/
	LOAD
	P43 	/MICROVOLTS
	FMUL
	P42 	/MULTIPLICATION
/
	FDIV
	SCLFAC
	FMUL
	SCLFIX
	FIX
	FAC
	ISTOR1
	FUDG
	LOAD
	SCLFAC
	STORE
	P45 	/FOR PLOTTING
/
FUDGX,	JMP
	EJECT
GETFIX,	RSW
	BCL I
	7770
	MUL I
	3
	ADA I
	SCLTAB
	STC .+2
	LOAD
	0
	RSW
	ROL 10
	APO I
	JMP .+3
	RECIP
	FAC
	FMUL
	P43
	STORE 
	SCLFAC
	JMP F1
/
GETINS,	LOAD
	INSCAL
	STORE
	SCLFAC
	JMP 0
	EJECT
/FIXED SCALE TABLE
/
FONE,	1
	2000
	0
/
SCLTAB,	2
	2000
	0
/
	2
	3000
	0
/
THRE,	3
	2000
	0
/
	3
	2400
	0
/
FTEN,	4
	2400
	0
/
	5
	3100
	0
/
SIX,	6
	3100
	0
/
	7
	3100
	0
/
SCLFIX,	5
	3106
	2144
/
ELV,	
VSCL,	11
	2000
	0
/
THOU,	12
	3720
	0
/
XSCL,	11
	2004
	0
/
ASCL,	10
	3770
	0
/
F2THOU,	13
	2000
	0
	EJECT
/SCALE BANK 7 DATA
/
DDAT,	LDA
	0
	STC DDATX
/
	LDF 7
	SET I 5
	2377
	SET I 7
	-1000
/
DSCLA,	LDA I 5
	MUL
	4\FUDG
	ROL 6
	BCL I
	77
	STC FUDG+1
	QAC
	SCR 5
	LZE
	COM
	BCL I
	7700
	ADD FUDG+1
	STA 5
	XSK I 7
	JMP DSCLA
/
DDATX,	JMP
	EJECT
/CODE TO GET THE CURSOR POINTS
/
GETCP,	LDA
	0
	STC X7
/
	ADD DT3
	ADA I
MONE,	-1
	APO
	COM
	MUL
	PSKP
/
	BSE
	DST
	STC RW
	LDF 6
	SFLOAT
RW,	0
	FDIV
	ASCL
	LDF 7
	FMUL
	P43
	FMUL
	P42
	STORE
	TEM1 	/Y
/
	ADD RW
	BSE I
	1000
	STC .+3
	LDF 6
	SFLOAT
	0
	FDIV
	ASCL
	LDF 7
	FMUL
	P43
	FMUL
	P42
	FMUL
	FAC
	STORE
	TEM3 	/VAR
/
	SFLOAT
	RW
	FSUB
	F2THOU
	FMUL
	MSEC
	LDA
	P0
	ROR 1
	APO
	JMP .+3
	FSUB
	BDLY
	STORE
	TEM2 	/X
/
X7,	JMP
	EJECT
/BUFFERS
PSKP,	0
BDLY,	*.+3
TEM,	*.+3
TEM1,	*.+3
TEM2,	*.+3
TEM3,	*.+3
MSEC,	*.+3
FUDG,	*.+3
SCLFAC,	*.+3
INSCAL,	7
	3100
	0
ONE,	1
/
NAMBUF,	7474
	4040
	4040
	4040
	4043
/
DATTYP,	2440
	4040
	4040
	4034
/
	7474
NBUF,	4016
	4040
	4040
	4043
/
PBUF,	4020
	4040
	4040
	4043
/
RMSBUF,	2615
	4040
	4040
	4040
	4040
	4034
/
ZER,	7460
	3434
/
ORDBUL,	7474
	4040
	4040
	4040
	4040
	3434
/
ORDBUH,	7474
	4040
	4040
	4040
	4040
	3434
ABSBUF,	7440
	4040
	4040
	4034
/
	7474
CXB,	4030
	4040
	4040
	4040
	4040
	4043
CYB,	3161
	4040
	4040
	4040
	4040
	4043
CSB,	3162
	4040
	4040
	4040
	4040
	4034
/
KEYBUF,	0
	0
	0
	0
	0
	4040
	4543
	EJECT
/THE COMMAND BUFFER WHICH
/DRIVES THE DISPLAY
/
DISBUF,	
/
	0
	0
	0 	/X
	-352 	/Y
	LDF 5
	ORDBUL
	4001
/
	-0
	0 	/LINE
	140 	/X
Y3,	-352
	140 	/X
Y4,	246 	/Y
	0
	4001
/
	0
	0
	0 	/X
	240 	/Y
	LDF 5
	ORDBUH
	4001
/
	0
	0
	0 	/X
	340 	/Y
	LDF 5
	NAMBUF
	4001
/
	0
	0
	120 	/X
	-42 	/Y
	LDF 5
	ZER
	4001
/
	-0
	0 	/LINE
C140,	140 	/X
Y1,	-42 	/Y
	540 	/X
Y2,	-42 	/Y
	0
	4001
/
	0
	0
DX1,	640 	/X
	-42 	/Y
	LDF 5
	ABSBUF
	4001
/
	0
	0
	540 	/X
	340 	/Y
	LDF 5
	NBUF-1
	4001
/SCALERS
/
DATS,	0
	0
	540
	-300+1
	LDF 5
	CXB-1
	4001
/
	-0
	0
	40 	/X
	130 	/Y
	40 	/X
	154 	/Y
	0
	4001
	-0
	0
DVL,	40 	/X
	130 	/Y
DVX,	71 	/X
	130 	/Y
	0
	4001
/
/HERE IS DATA
/
	-0
DT1,	2 	/1=BAR, 2=POINT
	140 	/X
	-42 	/Y
	LDF 7
	2400 	/LOC
DT2,	400 	/BUFSIZ
DT3,	0 	/CURSOR
DT4,	0 	/SCALE
DT5,	1 	/DATSPAC
DT6,	1 	/SCOSPAC
DT7,	0 	/CURSOR RET
	4001
/
/SD
/
STBUF,	-0
	2
	140 	/X
SDY,	0 	/Y
	LDF 7
	3000 	/LOC
DT8,	400 	/BUFSIZ
DT8A,	0 	/CURSOR
	0 	/SCALE
DT9,	1 	/DATSPAC
DT10,	1 	/SCOSPAC
	0
	4001
	4000
AA,	
	EJECT
/SPECIAL SUPPORT FOR DISPLAY
	SEGMNT 7
/
/BLOCK 44
	*20
OPTTST,	LSW
	LIF 5
	ROL 1 	/BIT 1
	APO
	JMP BASET
	LIF 7
	ROL 1 	/BIT 2
	APO
	JMP NEWSRT
	ROL 4 	/BIT 6
	APO
	JMP INVDIS
	ROL 3 	/BIT 9
	APO
	JMP INCOM
	ROL 2
	APO
	JMP SCALIN
/
R1,	LIF 5
	JMP LISN
/
NEWSRT,	RSW
	BCL I
	7477
	SCR 6
	BSE I
	2000
	LDF 5
	STA
	2\DST
/
R2,	LIF 5
	JMP LSCN+2
/
INVDIS,	LDA
	P17
	COM
	STC 7
	LDF 6
	SET I 6
	3777
	LDA I 6
	COM
	STA 6
	XSK I 7
	JMP .-4
	JMP R2
/
INCOM,	IOB 11
	4104
	272
	7
	CMES
	JMP .-5
	IOB 11
	0113
	-34
	7
	P24
	JMP .-5
	IOB 1
	13
	.+3
	JMP .-3
	IOB 5
	IOB 11
	7704
	-3
	0
	212
	JMP .-5
	JMP R1
	EJECT
KIGNOR,	LOAD
	ZIP
	LDF 5
	STORE
	2\TEM1
	STORE
	2\TEM2
/
R3,	LOAD
	2\TEM2
	LDF 7
	LIF 5
	JMP KA-1
/
KINSRT,	LDA I
	XMS
	JMP TYPO
	JMP INUMB
	LDF 5
	STORE
	2\TEM2
	LDA I
	YMS
	JMP TYPO
	JMP INUMB
	LDF 5
	JMP R4
/
TYPO,	STC .+7
	ADD 0
	STC .+7
	IOB 11
	4104
	272
	7
	0
	JMP .-5
	JMP
/
INUMB,	LDA
	0
	STC INUX
	IOB 11
	0113
	215
	4
	INBUF
	JMP .-5
	IOB 1
	13
	.+3
	JMP .-3
	IOB 5
	LDF 4
	INPUT
	INBUF
INUX,	JMP
/
XMS,	3040
	2601
	1472
/
YMS,	3140
	2601
	1472
/
CMES,	4543
	0317
	1515
	0516
	2472
SCALMS,	2303
	0114
	0572
/
ZIP,	3777
	3777
	3777
	EJECT
KINTR,	JMP ADDUP
	JMP R3
/
KAVG,	JMP ADDUP
	JMP R5
/
SCALAV,	JMP ADDUP
	LOAD
	2\TEM2
	FMUL
	2\MSEC
	STORE
	2\TEM2
R5,	LOAD
	2\TEM1
	FDIV
	2\TEM2
	JMP R4
/
KVRMS,	JMP MULUP
	LOAD
	2\TEM1
	FDIV
	2\TEM2
	SQRT
	FAC
/
R4,	STORE
	2\TEM1
	FZER
	STORE
	2\TEM3
	JMP R3
	EJECT
ADDUP,	LDA I
	JMP MN
	STC MT
	ADD 0
	STC KDATX
	JMP KDAT
/
MULUP,	LDA I
	NOP
	STC MT
	ADD 0
	STC KDATX
/
KDAT,	LDF 5
	FZER
	STORE
	2\TEM1
	STORE
	2\TEM2
	SRO I
	5252
	JMP DOIT
	LDA
	2\RW
	STC CRW
	STC CT
	JMP KDATX
/
DOIT,	LDA
	2\RW
	STC NRW
/
GRW,	LDF 6
	SFLOAT
CRW,	2000
	LDF 5
	FDIV
	2\ASCL
	FMUL
	1445		/P43
	FMUL
	1442		/P42
MT,	JMP
	FMUL
	FAC
MN,	FADD
	2\TEM1
	STORE
	2\TEM1
	ADD C1
	ADM I
CT,	0
	LDA
	CRW
	SAE I
NRW,	0
	SKP
	JMP ADDDON
	ADA I
C1,	1
	STC CRW
	JMP GRW
/
ADDDON,	SFLOAT
	CT
	STORE
	2\TEM2
KDATX,	JMP
/
SCALIN,	LDA I
	SCALMS
	JMP TYPO
	JMP INUMB
	LDF 5
	STORE
	2\INSCAL
	JMP R2
/
//PBLOCK
	NOLIST
/PARAMETER BLOCK ASSIGNMENTS
/
	P0=3400		/DATA TYPE
	P1=3401		/CURRENT CHAN.
	P2=3402		/CURRENT CHAN.
	P3=3403		/DATA CHAN.
	P4=3404		/DATA CHAN.
	P5=3405		/CONTINGENCY CH
	P6=3406		/CONTINGENCY CH
	P7=3407		/TRUE CONTING.
	P10=3410	/FALSE CONTING.
	P11=3411	/CONTING. WIDTH
	P12=3412	/TRUE CONTING.
	P13=3413	/FALSE CONTING.
	P14=3414	/CONTING. WIDTH
	P15=3415	/CHAN INVERSION
	P16=3416	/CHAN INVERSION
	P17=3417	/NO.SAMP IN SEG
	P20=3420	/NO.SEG IN ENSM
	P21=3421	/NO. ENSEMBLES
	P22=3422	/
	P23=3423	/BASELINE PNTS
	P24=3424	/TAPE DELAY
	P25=3425	/ENSEMBL DELAY
	P26=3426	/CLOCK RATE
	P27=3427	/CLOCK TICS
	P30=3430
	P31=3431
	P32=3432
	P33=3433
	P34=3434
	P35=3435
	P36=3436
	P37=3437	/TAPE SPEED UP
	P40=3440	/TAPE SPEED UP
	P41=3441	/TAPE SPEED UP
/
/FLOATING POINT VARIABLES
/
/
	P42=3442	/MULT FACTOR
	P43=3445	/UV PER VOLT
	P44=3450	/SEG. LENGTH
	P45=3453	/TEMP
	P46=3456	/BASELINE DELAY
	P47=3461	/CONTING WIDTH
	P50=3464	/BNDA1 MIN
	P51=3467	/BNDA1 MAX
	P52=3472	/BNDA2 MIN
	P53=3475	/BNDA2 MAX
	P54=3500	/BNDA3 MIN
	P55=3503	/BNDA3 MAX
	P56=3506	/BNDA4 MIN
	P57=3511	/BNDA4 MAX
	P60=3514	/BNDA5 MIN
	P61=3517	/BNDA5 MAX
	P62=3522	/BNDB1 MIN
	P63=3525	/BNDB1 MAX
	P64=3530	/BNDB2 MIN
	P65=3533	/BNDB2 MAX
	P66=3536	/BNDB3 MIN
	P67=3541	/BNDB3 MAX
	P70=3544	/BNDB4 MIN
	P71=3547	/BNDB4 MAX
	P72=3552	/BNDB5 MIN
	P73=3555	/BNDB5 MAX
	P74=3560	/PF MIN
	P75=3563	/PF MAX
	P76=3566	/TEMP
	P77=3571	/TRUE VOLTS
	P100=3574	/FALSE VOLTS
	P101=3577	/TEMP
	P102=3602	/V RMS
	P103=3605	/VRMS VAR
/
/FROM NOW ON DESCRIPTION IS FOUND OVER
/THE DEFINED VARIABLE.
/
/AX,A1,A1CNT
	P104=3610
/AXVAR,A1VAR,A1CNTVAR
	P105=3613
/AY,A2,A1INT
	P106=3616
/AYVAR,A2VAR,A1INTVAR
	P107=3621
/BX,A3,A1MN
	P110=3624
/BXVAR,A3VAR,A1MNVAR
	P111=3627
/BY,A4,A2CNT
	P112=3632
/BYVAR,A4VAR,A2CNTVAR
	P113=3635
/CX,A5,A2INT
	P114=3640
/CXVAR,A5VAR,A2INTVAR
	P115=3643
/CY,B1,A2MN
	P116=3646
/CYVAR,B1VAR,A2MNVAR
	P117=3651
/DX,B2,A3CNT
	P120=3654
/DXVAR,B2VAR,A3CNTVAR
	P121=3657
/DY,B3,A3INT
	P122=3662
/DYVAR,B3VAR,A3INTVAR
	P123=3665
/EX,B4,A3MN
	P124=3670
/EXVAR,B4VAR,A3MNVAR
	P125=3673
/EY,B5,A4CNT
	P126=3676
/EYVAR,B5VAR,A4CNTVAR
	P127=3701
/FX,PF,A4INT
	P130=3704
/FXVAR,PFVAR,A4INTVAR
	P131=3707
/FY,DC,A4MN
	P132=3712
/FYVAR,DCVAR,A4MNVAR
	P133=3715
/GX,GX,A5CNT
	P134=3720
/GXVAR,GXVAR,A5CNTVAR
	P135=3723
/GY,GY,A5INT
	P136=3726
/GYVAR,GYVAR,A5INTVAR
	P137=3731
/HX,HX,A5MN
	P140=3734
/HXVAR,HXVAR,A5MNVAR
	P141=3737
/HY,HY,B1CNT
	P142=3742
/HYVAR,HYVAR,B1CNTVAR
	P143=3745
/IX,IX,B1INT
	P144=3750
/IXVAR,IXVAR,B1INTVAR
	P145=3753
/IY,IY,B1MN
	P146=3756
/IYVAR,IYVAR,B1MNVAR
	P147=3761
/JX,JX,PF
	P150=3764
/JXVAR,JXVAR,PFVAR
	P151=3767
/JY,JY,DC
	P152=3772
/JYVAR,JYVAR,DCVAR
	P153=3775
/COMMAND DECODER ASSIGNMENTS
/
/
	STOP=JMP 20
	SCAN=JMP 21
	STRSCN=JMP 21
	INUNIT=JMP 22
	STORIT=JMP 23
	GETNAM=JMP 24
	GETFST=JMP 24
	GETNXT=JMP 25
	GETINI=JMP 26
	DIRINI=JMP 26
	DIRLST=JMP 27
	ASSIGN=JMP 30
	DEASS=JMP 31
	OUTUNIT=JMP 32
	LODBLK=JMP 33
	RUNBLK=JMP 34
	FIND=JMP 35
	CALL=JMP 37
	UNCALL=JMP 40
	RUNPRG=JMP 41
	INTRACT=JMP 42
	MESOUT=JMP 43
	DISK=JMP 44
	TABINI=JMP 45
	TABTYP=JMP 46
	MISSNG=JMP 47
	TABGET=JMP 50
	TABPUT=JMP 51
	TABZER=JMP 52
	MAKDIL=JMP 53
/COMMAND LOCATIONS.
	FILNAM=2320
	WORD1=2323
	WORD2=2324
	INBUF=2325
/COMMAND NUMBERS.
	GET=4
	YES=17
	NO=20
	SAMPL=21
	TABLE=22
	GO=23
	NEXT=24
	CU=25
	CURSOR=25
	CONT=26
	ALL=27
	AVG=30
	A=31
	B=32
	C=33
	D=34
	E=35
	F=36
	G=37
	H=40
	II=41
	J=42
	PLOT=43
	PRINT=44
/EXEC3 ASSIGNMENTS
/
	OPR=500
	IOF=6002
	ION=6001
	EXC=1710
	IOCALL=511
	AWAKE=501
	QUIT=505
	PAUSE=507
	IOCLR=502
	SETCON=510
	SETCLK=503
	PLINE=524
	READ=512
	WRITE=532
	SETDSK=513
	 
/DEVICE ASSIGNMENTS
/
	KBD=13
	TLP=4
	LPT=24
	BPLT=30
	PLT=25
	CLK=2
	SCOPE=26
/FLOATING POINT DEFINITIONS.
/
	FAC=0
	STARTE=740
	FSUB=741
	FMUL=742
	FDIV=743
	LOAD=744
	STORE=745
	SETWRD=746
	INPUT=747
	OUTPUT=750
	ISTOR1=751
	SQRT=752
	DFLOAT=753
	SFLOAT=754
	FIX=755
	FADD=756
	ISTOR2=757
	STARTF=760
	FCOMP=761
	FZER=762
	FAPO=763
	FAZE=764
	RECIP=765
	NEXTIN=766
	SETIN=767
	SETOUT=770
	OUTBUF=771
	PACFAC=772
	SACFAC=773
	FACAC=774
	UNFIX=775
/
	LIST
	 
/// END VIEW
/DEC 73
/NDC