Directory of image this file is from
This file as a plain text file

	*1400
/
/NON-RESIDENT SETUP MODULE. HANDLES INITIALIZATIONS
/AND MODE CHANGES VIA OPERATE 7 INSTRUCTIONS.
/
	-SUBM		/INDICATOR THAT THIS IS SETUP MOD
	SPA
	JMP	RET
	TAD	(-10
	SMA
	JMP	RET
	TAD	(JMP I ETB+1
	DCA	.+1
	JMP	.
	S0
	RST
	SETIO
	SET3
	SET4
	SET5
	SET6
ETB,	RET
/
/WE ARE INITIALIZING SYSTEM
/
S0,	DCA	FFIM	/CLEAR FLIP FLOP IMAGE
	IAC
	DCA	IMOD
	DCA	OMOD
	TAD	(JMP SET5
	DCA	SETIO-1	/SETUP TO READ IN INITIALIZER
	TAD	(0111
	DCA	IOMOD
	IAC
	DCA	ODEV
	IAC
	DCA	IDEV
	DCA	TTACT
/
/STOP SWITCH WAS PRESSED
/
RST,	ICON		/STOP TAPE MOTION
	DCA	TIFLG
	SP1
	DCA	JOBS
	CLC
	DCA	PFLG
	CLC
	DCA	RFLG
	CLC	
	DCA	TFLG
	CLC
	DCA	T2FLG
	CLC
	TAD	(BUFFER
	DCA	ICHR
	TAD	(BUFFER
	DCA	CFLG
	DCA	LFLG
	CLC
	DCA	LCNT
	TAD	FFIM
	AND	(3
	IACF
	DCA	FFIM
	CLC
	DCA	DOSWT
	ICA
	11
	ICA
	10
	TCF
	T2XF
	CLON
	CLOF
	CCLR
	DCMA
	KRB
	LCF
	CLA
	JMP	HALT

/
/I-O MODE SETUP. 
/
/ I-O FORMAT WORD CONTENTS:
/	BITS 0-2 = TAPE DRIVE ASSIGNMENT
/	BITS 3-4 = UNUSED
/	BIT 5 -- = INPUT MODE. 1 IF ASCII, 0 IF LINC CODE
/	BITS 6-8 = INPUT DEVICE IF NON ZERO
/	BITS 9-11= OUTPUT DEVICE IF NON ZERO
/
/ INPUT AND OUTPUT DEVICES
/	0 = NONE
/	1 = TELETYPE NUMBER ONE
/	2 = TELETYPE NUMBER TWO
/	3 = UNASSIGNED
/	4 = UNASSIGNED
/	5 = UNASSIGNED
/	6 = LINE PRINTER
/	7 = PAPER TAPE READER AND PUNCH
/
SETIO,	SKWB
	JMP	GETIO
	JMS	GETP1
	TAD	IOMOD
	AND	(3000
	DCA	IM1
	TAD	SBN
	SMA
	JMP	SET1
	AND	(3000
	DCA	IM1
	TAD	IM1
	RTL
	RTL
	AND	(3
	DCA	TEMP
	TAD	FFIM
	AND	(7774
	TAD	TEMP
	IACF
	DCA	FFIM
SET1,	CLA
	TAD	IOMOD
	AND	C7
	DCA	IM2
	TAD	SBN
	AND	C7
	SNA
	JMP	SET2
	DCA	ODEV
	TAD	ODEV
	DCA	IM2
	JMP	SET2
GETIO,	TAD	IOMOD
	JMP	DOGOA
IM1,	0
IM2,	0
/
/END OF PAGE SIX OF SETUP MODULE
/
	*1600
SET2,	TAD	IOMOD
	AND	(170
	DCA	IM3
	TAD	SBN
	AND	C70
	SNA CLA
	JMP	SET2A
	TAD	SBN
	AND	(170
	DCA	IM3
	TAD	IM3
	CLL RAR
	RTR
	AND	C7
	DCA	IDEV
	TAD	IM3
	AND	(100
	SZA CLA
	IAC
	DCA	IMOD
	TAD	FFIM
	AND	(7757
	IACF
	DCA	FFIM
SET2A,	TAD	IM1
	TAD	IM2
	TAD	IM3
	DCA	IOMOD
	TAD	SBN
	AND	C70
	SNA CLA
	JMP	DOGO
	TAD	IDEV
	DCA	TTACT
	JMP	DOGO
IM3,	0
SET3,	TAD	KSER
	DCA	TEMP
	TAD I	TEMP
	DCA	TTACT
	TAD	IOMOD
	AND	(7700
	DCA	IOMOD
	TAD	TTACT
	RTL CLL
	RAL
	TAD	TTACT
	TAD	IOMOD
	DCA	IOMOD
	TAD	TTACT
	DCA	IDEV
	TAD	IDEV
	DCA	ODEV
	JMP	KSER1
/
/RELEASE THE TELETYPE
/
SET4,	DCA	TTACT
	TAD	FFIM
	AND	(7757
	IACF
	DCA	FFIM
	JMP	RET
/
/CONTROL C HAS BEEN SELECTED
/
SET5,	TAD	(142
	DCA	MEMB	/SET UP TO INITIAL CONDITION
	TAD	(3
	DCA	SBN
	JMS	SETG
	JMS	STMEM
	AND	C70
	DCA	CEXT
	TAD	(1000
	DCA	DEXT
	TAD	(4400
	DCA	DADR
	JMS	DREAD
	TAD	(1404
	DCA	LNCP
	DCA	LNCA
	JMP	GO	/START THE LINC
/
/END OF NON-RESIDENT SETUP MODULE
/