File CHAR.SB (8k SABR macro assembler source file)

Directory of image this file is from
This file as a plain text file

/CHAR.SB
/	CHARACTER PACKING/UNPACKING ROUTINES
/	GEORGE GONZALEZ
/	CALL PACK(I,X)
/	PACKS ARRAY I (6A1) INTO X (A6)
/
////////
/	CALL UNPACK(X,I)
/	UNPACKS X (A6) INTO I (6A1)
/
//////////////
	ENTRY	PACK
	ENTRY	UNPAC
ABSYM	X0	10
ABSYM	X1	11
ABSYM	TMP	7
OPDEF	TADI	1400
OPDEF	DCAI	3400
OPDEF	BSW	7002

PACK,	0
P,	0
	JMS	ARGS	/GET ARGS
	JMS	PAC	/PACK 2
	JMS	PAC	/PACK 2 MORE
	JMS	PAC	/AND 2 MORE
	RETRN	PACK

UNPAC,	0
U,	0
	TAD	UNPAC
	DCA	PACK
	TAD	U
	DCA	P	/MOVE CALL ADDR. TO PACK

	JMS	ARGS

	JMS	UNP	/UNPACK 2 BYTES
	JMS	UNP
	JMS	UNP
	RETRN	PACK	/RETURN THRU PACK!!!!!!!!!!!!


UNP,	0
	JMS	GET
	DCA	TMP
	TAD	TMP
	JMS	OUT
	TAD	TMP
	BSW
	JMS	OUT
	JMP I	UNP

OUT,	0
	AND	(7700
	TAD	(40
	JMS	PUT
	JMP I	OUT

PUT,	0
F2,	HLT
	DCAI	X1
	JMP I	PUT

GET,	0
F1,	HLT
	TADI	X0
	JMP I	GET

PAC,	0
	JMS	GET
	AND	(7700
	DCA	TMP
	JMS	GET
	AND	(7700
	BSW
	TAD	TMP
	JMS	PUT
	JMP I	PAC


ARGS,	0
	TAD	PACK
	DCA	F
F,	HLT
	TADI	P
	DCA	F1
	INC	P
	STA
	TADI	P
	DCA	X0
	INC	P
	TADI	P
	DCA	F2
	INC	P
	STA
	TADI	P
	DCA	X1
	INC	P
	JMP I	ARGS

	END

Feel free to contact me, David Gesswein djg@pdp8online.com with any questions, comments on the web site, or if you have related equipment, documentation, software etc. you are willing to part with. I am interested in anything PDP-8 related, computers, peripherals used with them, DEC or third party, or documentation.

PDP-8 Home Page PDP-8 Site Map PDP-8 Site Search