File COMZER.SB (8k SABR macro assembler source file)

Directory of image this file is from
This file as a plain text file

/COMZER.SB
/	CALL COMZER(LOW,HIGH)
/	ZEROES COMMON STORAGE FROM VARIABLE 'LOW' TO
/	VARIABLE 'HIGH'.
/	DOES NOTHING IF 'HIGH' PRECEDES 'LOW'
/	PRINTS 'COMZ ERROR' IF 'HIGH' OR 'LOW' IS NOT IN COMMON

OPDEF	TADI	1400
OPDEF	DCAI	3400
ABSYM	X0	10
ABSYM	CDF10	6211
ABSYM	HIGH	7
	ENTRY	COMZE
MCOMM,	-6211
ERRTXT,	TEXT	"COMZ"

COMZE,	0
C,	0
	TAD	COMZE
	DCA	F
F,	HLT	/CHANGE TO CALLER'S FIELD
	TAD	C
	DCA	F	/GET PARAM ADDR
	TADI	F	/GET LOW FIELD
	TAD	MCOMM	/=1?
	SZA CLA
	JMP	COMERR	/IF NOT FIELD  1
	INC	F
	STA
	TADI	F
	DCA	X0
	INC	F
	TADI	F
	TAD	MCOMM	/=1?
	SZA CLA
	JMP	COMERR	/IF BAD FIELD
	INC	F
	TADI	F
	CIA
	DCA	HIGH

	CDF10

LOOP,	CLA CLL
	TAD	HIGH
	TAD	X0	/DONE?
	SZL CLA
	JMP	RTN	/YES, RETURN
	DCAI	X0	/NO, ZERO OUT ONE MORE
	JMP	LOOP	/MORE TO COME

RTN,	TAD	C
	TAD	(4	/SKIP ARGS
	DCA	C
	RETRN	COMZE

COMERR,	CALL	1,ERROR	/OOPS.. BAD VARS!!!!
	ARG	ERRTXT
	CALL	0,EXIT
	END



Feel free to contact me, David Gesswein djg@pdp8online.com with any questions, comments on the web site, or if you have related equipment, documentation, software etc. you are willing to part with.  I am interested in anything PDP-8 related, computers, peripherals used with them, DEC or third party, or documentation. 

PDP-8 Home Page   PDP-8 Site Map   PDP-8 Site Search