/ DEFECT ROUTINES				3/16/77
/
/
	FIELD DEF1FLD%10
	*300

MEMPTR=40
MEMTBL=2200
DBRI50=	6502
DBCI50=	6503
DBRI52=	6522



CH1LOC,	0		/CHANNEL 1 LOCATION IN THE MEMORY TABLE
DEFCT1,	0
CH1FLR,	0

	PAGE
/
/
/
/%R	PROCESS SHEET DEFECT DATA FOR CHANNEL 1
/
/%TW	THIS ROUTINE IS CALLED FROM THE JUMP TABLE AS
/	EACH SHEET BOUNDRY (YET TO BE CHOPPED) CROSSES THE 
/	INSPECTION POINT FOR CHANNEL 1.  IF CHANNEL 1
/	IS ENABLED, THE DEFECT DATA FOR THIS SHEET AND
/	THE FAILURE FLAG FROM SELF CHECK ARE "OR"ED 
/	INTO THE DEFECT MEMORY TABLE AT THE CHANNEL 1
/	POSITION.  THIS DATA IS LATER USED BY "PRODCT"
/	TO DETERMINE THE QUALITY OF THIS SHEET.
/
/
/%R	CHANNEL 1 RESOLUTION HANDLER
/
/%TW	COME HERE FROM THE JUMP TABLE AFTER THE RESOLUTION
/	AREA FOR CHANNEL 1 HAS PASSED THE INSPECTION
/	POINT.  THE RESOLUTION AREA IS A SMALL LENGTH
/	OF PRODUCT FOLLOWING THE LAST SHEET BOUNDARY FOR
/	CHANNEL 1.  DEFECTS APPEARING IN THE RESOLUTION
/	AREA BETWEEN TWO SHEETS WILL CAUSE BOTH SHEETS
/	TO BE REJECTED.  ANY DEFECT DATA WHICH HAS COME IN
/	SINCE "DEFCH1" WAS LAST CALLED IS "OR"ED WITH
/	THE DEFECT DATA IN THE DEFECT MEMORY TABLE FOR
/	THE SHEET WHICH JUST PASSED CHANNEL 1.  THE NEW DATA
/	IS LEFT IN "DEFCT1" FOR THE NEXT CALL TO "DEFCH1".
/
/




TASK=	DEF1
CUR=	DEF1FLD
INIWT=	RUNWT
VERS=	1

TASK2=	RES1
CUR2=	DEF1FLD
INIWT=	RUNWT
VERS2=	1



	FIELD DEF1FLD%10
	*DEF1LOC
/
/
/
/%RP	PROCESS SHEET DEFECT DATA FOR CHANNEL 1
/
/
START,	DBRI50		/IS MAST IN THE "TEST" MODE ?
	AND (0040)
	SZA CLA
	JMP .+4		/NO, GO ON.

	DBRI52		/IS THIS CHANNEL DISABLED ?
	AND (0004)
	SZA CLA
	JMP DEFC1A	/YES, JUST EXIT.

	TAD CH1LOC	/FORM ADDRESS POINTER INTO MEMORY
	TAD MEMPTR	/ TABLE AND SAVE THE CURRENT
	AND (0177)	/ LOCATION OF THE CHANNEL POINTER
	TAD (MEMTBL)	/ FOR THE RESOLUTION ROUTINE.
	DCA CH1PTR

	DCA CH1FLR	/NO, CLEAR THE CHANNEL DISABLE FLAG

	TAD I CH1PTR	/GET THE DATA CURRENTLY IN THE
	MQL		/MEMORY TABLE AND "OR" IN THE DEFECT
	DBRI50		/AND FAILURE DATA FOR THIS CHANNEL
	AND (0004)
	DBCI50
	MQA
	MQL
	TAD CH1FLR
	CLL RTL
	MQA
	DCA I CH1PTR	/RETURN THE DATA TO THE MEMORY TABLE
DEFC1A,	DCA DEFCT1	/CLEAR DEFECT STORAGE FOR THIS
			/ CHANNEL

	CLB
	CAL
	SUSPND
	JMP START
/
/
/
/%RP	CHANNEL 1 RESOLUTION ROUTINE
/
/
START2,	CLB
	TAD I CH1PTR	/"OR" DEFECT DATA INTO THE MEMORY
	MQL		/TABLE AT THE CHANNEL 1 LOCATION
	DBRI50
	AND (0004)
	DBCI50
	MQA
	DCA I CH1PTR

	CLB
	CAL
	SUSPND
	JMP START2


CH1PTR,	0		/MEMORY TABLE ADDRESS FOR THIS CHANNEL,
			/LEFT BY DEFCH1