Directory of image this file is from
This file as a plain text file

/ DIRECT SAMPLE TALLEY OUTPUT TO PROPER DEVICES	 1-SEP-91
/
/
/
/	DDDD   IIIII  RRRR   TTTTT   AAA   L
/	D   D    I    R   R    T    A   A  L
/	D   D    I    R   R    T    A   A  L
/	D   D    I    RRRR     T    A   A  L
/	D   D    I    R R      T    AAAAA  L
/	D   D    I    R  R     T    A   A  L
/	DDDD   IIIII  R   R    T    A   A  LLLLL
/
/
/

/
/EDIT HISTORY:
/
/06-JUL-91	(LHN)
/	1) CREATED THIS DATE
/
/
/22-AUG-91	(LHN)		FOR VERSION 4B
/	1)  DELETED TEST FOR GATEWAY COMM LINE UP/DOWN
/
/1-SEP-91	(LHN)
/	1)  ADDED MESSAGE TO INLOCK FOR GATEWAY FAILURE.
/

/
/	THIS TASK CONTROLS WHAT DEVICES RECIEVE THE SAMPLE 
/	TALLEY OUTPUT TEXT. THE TEXT CAN BE SENT TO THE 
/	LINE PRINTER (LPT) OR THE SICK GATEWAY (COMM). 
/	EITHER OF THESE DEVICES CAN BE ENABLED OR DISABLED 
/	BY COMMANDS PROCESSED BY 'USERCD'. FLAGS IN COMMON 
/	DETERMINE IF THE OUTPUT DEVICES ARE ACTIVE.
/
/
/	NOTE:  	THIS TASK MUST BE IN THE SAME FIELD AS
/		THE FORMAT TASK.
/


	TASK=	DIRTAL
	INIWT=	0
	CUR=	DIRTFLD
	VERS=	4


	FIELD DIRTFLD%10
	*DIRTLOC
/
START,	CLB
	CAL		/WAIT 'TIL THERE IS DATA FOR US
	RECEIVE
MADDR,	0
	CLB
	AC7775		/SAVE THE ADDRESS OF THE INPUT
	TAD MADDR	/ EVENT FLAG
	DCA MEVFLG

	TAD I MADDR	/GET THE MESSAGE PACKET LOCALLY
	ISZ MADDR
	MQL		/SET BIT TO SAY OUTBUF WORD POINTS
	TAD (1000)	/ TO THE DATA BUFFER.
	MQA
	DCA TALDA
	TAD I MADDR	/MOVE SECOND WORD OF PACKET.
	ISZ MADDR
	DCA TALDB
	TAD MADDR	/AND NOW THE THIRD WORD.
	DCA TALDC


DIRT1,	TAD ENBCOM	/IS GATEWAY TRANSMISSION ENABLED ?
	SNA CLA
	JMP DIRT2	/NO, GO ON.

	CAL		/YES, SEND MESSAGE PACKET TO THE
	SENDW		/ GATEWY TASK.
	GATEWY
	TALMSG

	CLB
	TAD I TALDC	/DID GATEWY SEND THE MESSAGE OK ?
	SMA CLA
	JMP DIRT2	/YES, GO ON.

	CAL		/NO, SEND INLOCK A MACHINE STOP 
	SENDW		/ REQUEST AND DISPLAY TRANSMISSION
	INLOCK		/ ERROR.
	ERRMSG

	CLB
	TAD ENBLPT	/IS THE PRINTER ENABLED ?
	SNA CLA		/IF IT IS, FORGET GATEWY.
	JMP DIRT1	/NO, GO TRY THE MESSAGE AGAIN,
			/ WE DO NOT WANT TO LOSE THE
			/ THE SAMPLE TALLEY DATA.			
/
DIRT2,	TAD ENBLPT	/IS THE PRINTER ENABLED ?
	SNA CLA
	JMP DIRXIT	/NO, GO ON.

	TAD TALMSG+5	/YES, ADJUST TEXT ADDRESS FOR LPT 
	TAD (3)		/ TO SKIP THE MESSAGE TYPE CODE.
	DCA TALMSG+5
	CAL		/SET MESSAGE PACKET TO THE LPT.
	SENDW
	LPT
	TALMSG

DIRXIT,	CLB		/POST THE MESSAGE EVENT FLAG.
	TAD MEVFLG
	CAL
	POST
	CDF CUR
	JMP START

MEVFLG,	0		/ADDRESS OF EVENT FLAG FOR INPUT.

TALMSG,	ZBLOCK 3	/LOCAL MESSAGE PACKET.
TALDA,	0
TALDB,	0
TALDC,	0

ERRMSG,	ZBLOCK 3	/INLOCK MESSAGE FOR ERROR.
	MOPM24+MSTINL	/STOP MACHINE AND SAY GATEWAY
			/ COMMUNICATION FAILURE.
/

	PAGE


	NOPUNCH		/ F4COMM FILE FOLLOWS
	XLIST 1