Directory of image this file is from
This file as a plain text file

/*** TSS/8 DTBOOT ***\
/
/THIS PROGRAM PUTS A SECONDARY
/BOOTSTRAP ONTO SYSTEM DUMP TAPE #1,
/BLOCK 0.  THIS BOOTSTRAP MAY BE
/LOADED AND EXECUTED, BY WAY OF
/THE OS/8 TAPE SYSTEM PRIMARY BOOTSTRAP.
/
/THIS PROGRAM WILL RUN UNDER TIMESHARING
/MODE.  MOUNT SYSTEM DUMP TAPE#1
/AS DTA0:.  TYPE: ".RU DTBOOT", AND IT
/WILL PROCEED TO WRITE OUT THE SECONDARY
/BOOTSTRAP.
/
/DISASSEMBLED, AND RE-ENCODED BY JOHN YOUNG
/	N-MUSD		23-FEB-76
/
/
/
XLIST
SRA=6417
ASD=6440
XLIST
CDI=	6203
DTRA=	6761
DTCA=	6762
DTXA=	6764
DTLA=	6766
DTSF=	6771
DTRB=	6772
DTLB=	6774
FIXTAB

*0000
	CLA CLL
	TAD	RESTRT
	SRA
	TAD	DEV
	ASD		/ASSIGN DTA0:
	SZA CLA		/DID WE GET IT?
	JMP	ERROR	/NOPE, TELL HIM
	TAD	DTBLK	/GET DTA CONTROL BLOCK
	DTXA		/EXECUTE IT.
	DTRB		/IF THERE'S AN ERROR, TELL HIM
	SPA CLA
	JMP	ERROR	/TELL HIM SOMETHING'S WRONG
	JMP	RESTRT+1

POINT,	0

RESTRT,	.+1
	HLT
	JMP	0	/TO RESTART, TYPE ".ST 0"

DEV,	4005		/DTA0:

DTBLK,	.+1
	40		/DTA0:, WRITE, FORWARD
	0		/BLOCK 0
	BOOT-1		/CORE ADDRESS -1

ERROR,	TAD	MSG
	DCA	POINT
	TAD I	POINT
	TLS
	SMA CLA
	JMP	ERROR+2
	JMP	RESTRT+1

MSG,	.
"D;"E;"C;"T;"A;"P;"E;" ;"E;"R;"R;"O;"R;15;4012

/THE FOLLOWING CODE WILL BE PLACED
/ON DTA0:. WHEN LOADED, IT WILL OVERLAY THE PRIMARY
/BOOTSTRAP ALREADY IN CORE.
/
/A FUNNY THING: THE DTSF;JMP .-1 LOOP
/THAT GETS OVERLAYED, IS THE SAME CODE
/IN THE SECONDARY; IT DIDN'T EVER KNOW IT
/GOT OVERLAYED.
/
/
DTAWC=	7754
DTACA=	7755
BLKNUM=	0
*0200
BOOT=	.

NOPUNCH
*7600
ENPUNCH

REBOOT,	DTRA
	AND	K7000
	TAD	K600	/REVERSE TAPE TO END ZONE
	DTLA
	DTSF
	JMP	.-1
	TAD	K220	/START READING FROM BLOCK 0
	DTLA
	JMP	START

K7000,	7000
K600,	600
K220,	220
K130,	130
KN101,	-101

GO=	JMP	.

START,	DTSF
	JMP	.-1
	DCA	DTAWC
	DCA	DTACA
	DCA	BLKNUM
	TAD	K130	/GO, FORWARD, CONTINUOUS, SEARCH
SEARCH,	DTXA
	DTSF
	SKP
	JMP	REBOOT	/IF THE SKIP IS TRUE, SOMEBODY (THING?) GOOFED.
	TAD	KN101
	TAD	BLKNUM	/IF THIS IS BLOCK 101, THIS IS BEGINNING OF INIT!
	SZA CLA
	JMP	SEARCH
	STA
	DCA	DTACA	/START AT LOCATION 0
	TAD	KN40
	DCA	BLKNUM	/READ IN 40 BLOCKS = 4K CORE
	TAD	K130	/READ, NORMAL, GO
READ,	DTXA
	TAD	KN200	/200 WORDS
	DCA	DTAWC
	TAD	K220
	DTLB		/PUT INIT INTO FIELD 2
	DTSF
	JMP	.-1
	DTRB		/ERROR?
	SPA CLA
	JMP	REBOOT	/YUP, RESTART
	ISZ	BLKNUM	/READ 40 BLOCKS YET?
	JMP	READ	/NO, GET ANOTHER
	TAD	K220	/STATUS REGISTER A  = 0
	DTXA		/STOP THAT TAPE!!
	CDI	20	/JUMP TO INIT, FIELD 2
	JMP	0

KN40,	-40
KN200,	-200

XLIST
GO
GO
GO
GO
GO
GO
GO
GO
GO
GO
GO
GO
GO
GO
GO
GO
GO
GO
GO
GO
GO
GO
GO
GO
GO
GO
GO
GO
GO
GO
GO
GO
GO
GO
GO
GO
GO
GO
GO
GO
GO
GO
GO
GO
GO
GO
GO
GO
GO
GO
GO
GO
GO
GO
GO
GO
GO
GO
GO
GO
GO
GO
GO
GO
GO
GO
GO
GO
GO
GO
GO
GO
GO
GO
GO
GO
XLIST
GO

$$$