Directory of image this file is from
This file as a plain text file

/ END OF ROLL SUMMARY CONTROL                   27-AUG-91
/
/
/
/	EEEEE   OOO   RRRR    SSSS  U   U  M   M
/	E      O   O  R   R  S      U   U  MM MM
/	E      O   O  R   R  S      U   U  M M M
/	EEEE   O   O  RRRR    SSS   U   U  M   M
/	E      O   O  R R        S  U   U  M   M
/	E      O   O  R  R       S  U   U  M   M
/	EEEEE   OOO   R   R  SSSS    UUU   M   M
/
/
/

/
/EDIT HISTORY:
/
/30-AUG-90	(LHN)
/	1) ADDED OPERATOR MESSAGE CODE TO INLOCK MESSAGE
/
/
/27-AUG-91	(LHN)		FOR VERSION 4B
/	1)  ADDED MESSAGE TO GATEWY TO REQUEST NEXT ROLL
/	      DATA IF NEEDED.
/


	TASK=	EORSUM
	CUR=	EORSMFLD
	INIWT=	0
	VERS=	1



	FIELD EORSMFLD%10
	*EORSMLOC
/
/
/%R	END OF ROLL SUMMARY CONTROL
/
/%TW	THIS SEGMENT IS CALLED FROM "MOPDEC", WHEN THE
/	OPERATOR PRESSES THE "END OF ROLL SUMMARY" PUSH
/	BUTTON.  IF: 1) THE MACHINE IS STOPPED, 2) THE
/	NEXT ROLL DATA HAS BEEN ENTERED, AND 3) THE 
/	STACKER HAS JUST BEEN CLEARED, THIS SEGMENT WILL
/	FORCE THE END OF ROLL SUMMARY TO BE SCHEDULED FOR
/	THE PRINTER AND WILL RESET MAST FOR THE NEXT 
/	PRODUCT ROLL.  IF ANY OF THESE CONDITIONS ARE
/	NOT MET, THE APPROPRIATE ERROR
/	MESSAGE IS DISPLAYED ON THE CRT.  WHEN THE 
/	OPERATOR HAS SATISFIED THE CONDITIONS, HE
/	MUST PRESS THE BUTTON AGAIN.
/
/
START,  CLB
	CAL
	SUSPND		/GO TO SLEEP 'TIL NEEDED

	DBRI50		/IS THE MACHINE RUNNING ?
	AND (4000)
	SNA CLA
	JMP EORC1	/NO, GO ON.
	CAL
	SEND
	INLOCK		/YES, OPEN THE MAST MONITOR INTERLOCK
	EORMG1
	JMP START	/RETURN FOR NOW.

EORC1,	CDF 30
	TAD I (NEWRNF)	/DO WE HAVE THE NEXT ROLL DATA ?
	CDF CUR
	SZA CLA
	JMP EORC2	/YES, GO ON.

	CAL		/NO, REQUEST NEXT ROLL DATA 
	SENDW		/ FROM THE GATEWAY.
	GATEWY
	NRDMSG
	CAL		/DISPLAY DATA NEEDED MESSAGE.
	SEND
	CRTMSG
	EORMG2
	JMP START	/RETURN FOR NOW.
/
EORC2,  CDF 10
	TAD I (SRODNF)	/HAS THE STACKER BEEN CLEARED ?
	CDF CUR
	SZA CLA
	JMP EORC3	/YES, GO ON.
	CAL
	SEND
	CRTMSG
	EORMG3
	JMP START	/RETURN FOR NOW.
EORC3,  CDF 10
	DCA I (SRODNF)	/CLEAR THE STACKER RUN OUT DONE FLAG.
	CDF CUR
	CLB IAC		/SET THE END OF ROLL SUMMARY
	DCA EORSFG 	/FLAG AND RUN "TALLEY"
	TAD (TALLEY)
	CAL
	RUN
	TAD (BUILD)	/SET UP FOR THE NEW CHOP SIZE
	CAL
	RUN

	TAD (SCREEN)	/REFRESH THE CRT
	CAL
	RUN

	CLB IAC		/FORCE START OF ROLL
	DCA STROLL	/SAMPLING
	JMP START


EORMG1, ZBLOCK 3	/OPEN MAST MONITOR INTERLOCK
	MSTINL+MOPM17

EORMG2, ZBLOCK 3	/DISPLAY "ENTER ROLL DATA"
	MOPM08

EORMG3, ZBLOCK 3	/DISPLAY "CLEAR THE STACKER"
	MOPM07

NRDMSG,	ZBLOCK 3	/REQUEST NEXT ROLL DATA
	0
	0
	0		/STATUS RETURN
	"N
	"R
	0
/

	PAGE

	NOPUNCH		/F2COMM FILE FOLLOWS
	XLIST 1