File HELLO.BA (BASIC source file)

Directory of image this file is from
This file as a plain text file

1 REMARKABLY TRANSLATED TO OS8 BASIC BY KAY R. FISHER ...DEC
2 PRINT PNT(0);PNT(0);PNT(0);PNT(29);PNT(0);
3 PRINT PNT(0);PNT(0);PNT(0);PNT(31);PNT(0);PNT(0);PNT(0);PNT(0);
4 DIM A$(26),D$(10)
10 PRINT "HELLO, MY NAME IS PETEY P. EIGHT."
20 PRINT\PRINT PNT(0);PNT(0);PNT(0);"WHAT'S YOUR NAME  ";\INPUT A$\PRINT
35 PRINT " HI THERE ";\GOSUB 500
36 PRINT ".  ARE YOU ENJOYING YOURSELF HERE"
40 PRINT"IN THIS WONDERFUL PLACE";
45 INPUT B$\PRINT
50 IF B$="YES" THEN 70
55 IF B$="NO" THEN 80
60 PRINT " ";\GOSUB 500
61 PRINT ", I DON'T UNDERSTAND YOUR ANSWER OF '";B$;"'."
65 PRINT "PLEASE ANSWER 'YES' OR 'NO'. DO YOU LIKE IT HERE"
66 PRINT"IN THIS CRAZY PLACE !!!";
67 GOTO 45
70 PRINT "OH, I'M GLAD TO HEAR THAT ";\GOSUB 500
71 PRINT
75 GOTO 100
80 PRINT "OH, SORRY TO HEAR THAT ";\GOSUB 500
81 PRINT ", MAYBE WE CAN"
85 PRINT "BRIGHTEN UP YOUR STAY A BIT"
100 PRINT
105 PRINT "SAY, ";\GOSUB 500
106 PRINT ", I CAN SOLVE ALL KINDS OF PROBLEMS"
110 PRINT "EXCEPT THOSE DEALING WITH GREECE. WHAT KIND OF"
115 PRINT "PROBLEMS DO YOU HAVE (ANSWER SEX, HEALTH, MONEY,"
120 PRINT "OR JOB)";
125 INPUT C$\PRINT
130 IF C$="SEX" THEN 200
132 IF C$="HEALTH" THEN 180
134 IF C$="MONEY" THEN 160
136 IF C$="JOB" THEN 145
138 PRINT "OH, ";\GOSUB 500
139 PRINT ", YOUR ANSWER OF '";C$;"' IS GREEK TO ME."
140 GOTO 250
145 PRINT "I CAN SYMPATHIZE WITH YOU ";\GOSUB 500
146 PRINT ". I HAVE TO WORK"
148 PRINT "VERY LONG HOURS FOR NO PAY -- AND SOME OF MY BOSSES REALLY"
150 PRINT "BEAT MY KEYBOARD. MY ADVICE TO YOU ";\GOSUB 500
151 PRINT ", IS"
153 PRINT "TO SELL IN THE EDUCATION MARKET. IT'S GREAT FUN."
155 GOTO 250
160 PRINT "SORRY, ";\GOSUB 500
161 PRINT ", I'M BROKE TOO. WHY DON'T YOU "
163 PRINT "SELL ENCYCLOPAEDIAS OR MARRY SOMEONE RICH OR STOP EATING"
165 PRINT "SO YOU WON'T NEED SO MUCH MONEY?"
170 GOTO 250
180 PRINT "MY ADVICE TO YOU ";\GOSUB 500
181 PRINT ", IS:"
185 PRINT "     1. TAKE TWO ASPRIN"
188 PRINT "     2. DRINK PLENTY OF FLUIDS (ORANGE JUICE, NOT BEER!)"
190 PRINT "     3. GO TO BED (ALONE)"
195 GOTO 250
200 PRINT "IS YOUR PROBLEM TOO MUCH OR TOO LITTLE";
205 INPUT D$\PRINT
210 IF D$="TOO MUCH" THEN 220
213 IF D$="TOO LITTLE" THEN 230
215 PRINT "DON'T GET ALL SHOOK UP ";\GOSUB 500
216 PRINT ", JUST ANSWER"
217 PRINT "THE QUESTION WITH 'TOO MUCH' OR 'TOO LITTLE'. WHICH IS IT";
218 GOTO 205
220 PRINT "YOU CALL THAT A PROBLEM?!! I SHOULD HAVE SUCH PROBLEMS!"
225 PRINT "IF IT BOTHERS YOU, TAKE A COLD SHOWER ";\GOSUB 500
226 PRINT"AND INTRODUCE ME TO THE SOURCE OF YOUR PROBLEM !!"
228 GOTO 250
230 PRINT "WHY ARE YOU HERE ";\GOSUB 500
231 PRINT "? YOU SHOULD BE"
235 PRINT "IN TOKYO OR NEW YORK OR AMSTERDAM OR SOMEPLACE WITH SOME"
240 PRINT "REAL ACTION."
250 PRINT
255 PRINT "ANY MORE PROBLEMS YOU WANT SOLVED, ";\GOSUB 500
260 INPUT E$\PRINT
270 IF E$="YES" THEN 280
273 IF E$="NO" THEN 300
275 PRINT "JUST A SIMPLE 'YES' OR 'NO' PLEASE, ";\GOSUB 500
276 PRINT "."
278 GOTO 255
280 PRINT "WHAT KIND (SEX, MONEY, HEALTH, JOB)";
285 GOTO 125
300 PRINT
302 PRINT "THAT WILL BE $5.00 FOR THE ADVICE, ";\GOSUB 500
303 PRINT "."
305 PRINT "PLEASE LEAVE THE MONEY ON THE TERMINAL. "
307 PRINT\PRINT\PRINT
310 PRINT "DID YOU LEAVE THE MONEY";
315 INPUT G$\PRINT
325 IF G$="YES" THEN 350
330 IF G$="NO" THEN 370
335 PRINT "YOUR ANSWER OF '";G$;"' CONFUSES ME, ";\GOSUB 500
336 PRINT ". PLEASE"
340 PRINT "RESPOND WITH A 'YES' OR 'NO'."
345 GOTO 310
350 PRINT "HEY, ";\GOSUB 500
351 PRINT "??? YOU LEFT NO MONEY AT ALL!"
355 PRINT "YOU ARE CHEATING ME OUT OF MY HARD-EARNED LIVING."
360 PRINT "RIP OFF, ";\GOSUB 500
361 PRINT ". *=*=*=*=*=*=*=*=*=*=*=*=*=*=*=*=*"
365 GOTO 390
370 PRINT "THAT'S HONEST, ";\GOSUB 500
371 PRINT ", BUT HOW DO YOU EXPECT"
375 PRINT "ME TO GO ON WITH MY PSYCHOLOGY STUDIES IF MY PATIENTS DON'T"
380 PRINT "PAY THEIR BILLS?"
385 PRINT\PRINT\PRINT "NOW LET ME TALK TO SOMEONE ELSE."
390 PRINT "NICE MEETING YOU ";\GOSUB 500
391 PRINT ". HAVE A NICE DAY!!"
400 FOR I=1 TO 3000
405 NEXT I
410 GO TO 2
500 PRINT A$;
510 RETURN
999 END



Feel free to contact me, David Gesswein djg@pdp8online.com with any questions, comments on the web site, or if you have related equipment, documentation, software etc. you are willing to part with.  I am interested in anything PDP-8 related, computers, peripherals used with them, DEC or third party, or documentation. 

PDP-8 Home Page   PDP-8 Site Map   PDP-8 Site Search