Directory of image this file is from
This file as a plain text file

/MODIFICATIONS TO ENABLE CONTROL OF MULTIPLE TERMINALS FROM K00
/
/BOB CURRIER
/NEWPORT-MESA UNIFIED SCHOOL DISTRICT
/
/DECEMBER 28, 1974	21:26:34
/

/
/*** MODS TO TS8 ***
/

*0114

OPRCON,	0			/CONSOLE CURRENTLY CONNECTED TO PHYSICAL K00
OLD,	0			/LAST JOB TO OUTPUT ON K00
HDR,	0			/ = 1 IF HEADER HAS BEEN PRINTED THIS TIME AROUND

/MODS TO SUBROUTINE PRINT
/
/MUST FIND SOMEWHERE TO FIT ALL THIS
/

*1214

	SNA CLA

*1216

	TAD TTCHAR		/GET OUR CHARACTER
	DCA TEMTTC		/STORE FOR LATER
	TAD I CONDDB
	AND C0037
	CLL RAR
	SZA CLA			/K00 OR K01 ?
	JMP PRINT3		/NOPE--
	TAD I CONDDB		/YES--
	SMA CLA			/^S MODE ?
	JMP PRINT4		/NO--
	TAD HDR
	SZA CLA			/HAS HEADER BEEN PRINTED ?
	JMP PRINT3		/YES
	JMS PUTHDR		/NO--OUTPUT IT
	ISZ HDR			/FLAG IT
	JMP PRINT3
PRINT4,	TAD I CONDDB		/COME HERE ON ^Q MODE
	AND C0037
	CLL RAR
	CML RAL
	CIA
	TAD OLD
	SZA CLA			/B=OLD ?
	JMS PUTHDR		/YES--OUTPUT A HEADER
	TAD I CONDDB		/NO-- OLD _ A
	AND C0037
	DCA OLD
	TAD OLD			/GET B'S OUTPUT DDB
	CLL CIA RAL
	SNA
	CLA CLL IAC RAL
	TAD CONDBA		/CONDBA (+ OR -) 2 =
	DCA TEMPRI		/THE NEW CONDBA
	TAD I TEMPRI
	DCA TEMPRI		/THE NEW CONDDB
	TAD I TEMPRI
	AND C3777
	TAD CK4000		/SET ^S
	DCA I TEMPRI
PRINT3,	TAD TEMTTC		/GET BACK OKLD TTCHAR
	DCA TTCHAR
	TAD I CONDBA

/
/ROUTINE TO PRINT HEADER
/
/THIS NEEDS TO BE LOCATED SOMEWHERE
/

PUTHDR,	0
	TAD KC215		/GET A CR
	JMS PUTH
	TAD KC212		/GET A LF
	JMS PUTH
	TAD I CONDDB		/GET OUR CONSOLE
	AND C0037
	TAD KC330		/ADD AN "X"
	JMS PUTH
	TAD KC251		/GET A ")"
	JMS PUTH
	JMP I PUTHDR

PUTH,	0
	DCA TTCHAR
	TAD I CONDBA
	STORE
	OUTSIZ
	NOP		/WE DONT CARE ABOUT IT IF IT DOESN'T FIT
	JMP I PUTH

/
/CONSTANTS FOR THE LAST COUPLE ROUTINES
/

TEMTTC,	0			/TEMP TTCHAR
TEMPRI,	0			/TEMP POINTER
KC215,	215
KC212,	212
KC330,	330
KC251,	251

/
/MODS TO CONIN
/

*2037

	SNA			/K00 ?
	TAD OPRCON		/YES - CONVERT TO LOGICAL K00

/
/MODS TO KBD
/


*3214

	TAD TTCHAR
	TAD KBDMCX
	CLL RAR
	SZA CLA			/^X OR ^Y ?
	JMP KBDXXX		/NO--
	TAD TTCHAR
	TAD KBDMCX
	DCA OPRCON		/STORE AS LOGICAL K00
KBDXXX,


/CONSTANTS NEEDED ABOVE

KBDMCX,	-230			/-^X
/
/MODS TO CONOUT
/

*6252

	JMP CONO10		/BUFFER EMPTY

/LOCATE THIS NEXT ROUTINE SOMEWHERE

CONO10,	TAD I CONDDB		/GET CONSOLE
	AND C0037
	CLL RAR
	SZA CLA
	JMP CONOU9		/NOT K00 OR K01
	CLL STA RAR		/DDB _ ^Q
	AND I CONDDB
	DCA I CONDDB
	TAD I CONDDB		/GET OTHER DDB
	AND C0037
	CLL CIA RAL
	SNA
	CLA CLL IAC RAL
	TAD CONDBA
	DCA TEMCON
	TAD I TEMCON
	SNA
	JMP CONOU9		/NO OUTPUT DDB
	DCA TEMCON
	TAD I TEMCON		/GET WORD 1 OF DDB
	SMA			/^S ?
	JMP CONOU9		/NOPE--
	AND C3777		/YES--WIPE IT OUT
	DCA I TEMCON		/AND REPLACE IT
	DCA HDR			/CLEAR OUT HDR FLAG
	TAD I CONDDB
	AND C0037
	CLL RAR
	CML RAL
	DCA OLD			/STORE AS OLD CONSOLE
	JMP CONOU9		/EXIT

TEMCON,	0