Directory of image this file is from
This file as a plain text file

/ MISCELLANEOUS ROUTINE                      24-JUL-78







	TASK=	MISC1
	CUR=	MISC1FLD
	INIWT=	0
	VERS=	1







	FIELD MISC1FLD%10
	*MISC1LOC
/
/
/%R	MISCELLANEOUS ROUTINE
/
/%TW	WATCH FOR A SPLICE AND RECALIBRATE THE INSPECTOR
/	AFTER THE SPLICE IS PAST CHANNEL 3. ALSO TURN ON
/	THE SPLICE COMMENT ON THE M.O.P. AND LOCK IN THE
/	SAMPLE TRAY UNTIL SPLICE IS IN THE SAMPLE TRAY
/
START,  CLB
	CAL
	SUSPND		/GO TO SLEEP 'TIL NEEDED

	CLB IAC		/HAS THE MACHINE CHECK MESSAGE
	TAD MCKMCT	/DISPLAY TIMED OUT ?
	SPA SNA
	DCA MCKMCT
	SNL CLA
	JMP MISC0	/NO, GO ON.
	CAL
	SEND
	CRT
	MISMG1
	JMP MISC2

MISC0,	TAD MCKDSP	/IS THE MACHINE CHECK FLAG SET ?
	SNA
	JMP MISC2	/NO, GO ON
	AND (7700)	/YES, FOR THE TRAY LETTER AND
	BSW		/PUT IT IN THE CRT TEXT
	TAD (4000)
	DCA I (CRTH22+11)

	TAD MCKDSP	/NOW FORM THE NUMBER OF 
	AND (0007)	/SHEETS AND PUT IT IN THE
	TAD (4060)	/CRT TEXT.
	DCA I (CTH22A)
	TAD (-400)	/SET THE MACHINE CHECK
	DCA MCKMCT	/MESSAGE COUNTER

	DCA MCKDSP	/CLEAR OUR FLAG.

	CAL		/SEND THE MESSAGE TO THE CRT
	SEND
	CRT
	MISMG2
/
MISC2,	CLB IAC
	TAD SPLMCT	/HAS THE SPLICE MESSAGE DISPLAY
	SPA SNA		/TIMED OUT ?
	DCA SPLMCT
	SNL CLA
	JMP MISC3		/NO, GO ON.
	CAL
	SEND
	CRT
	MISMG3

MISC3,	CLB
	CDF 10
	TAD I (SPLFLG)	/IS THE SPLICE DETECTED FLAG SET ?
	MQL		/SAVE IT
	DCA I (SPLFLG)
	ACL
	CDF CUR
	AND (0010)
	SNA CLA
	JMP MISC5	/NO, GO ON.
	CAL
	SEND
	CRT
	MISMG4

	TAD (-400)	/SET THE SPLICE MESSAGE DISPLAY
	DCA SPLMCT	/DELAY COUNTER.
	CLB CMA RTL	/SET UP THE INSPECTION RECAL DELAY.
	DCA INSPDY
	TAD (BELL)	/RING THE ALERT ALARM
	CAL
	RUN

	CDF 10
	ISZ I (SMTLKF)	/LOCK IN THE SAMPLE TRAY
	TAD (-55)
	DCA I (SMTLKD)	/SET THE SAMPLE TRAY UNLOCK DELAY.
	DBRI51		/IS THE SAMPLE OR A REJECT TRAY OUT ?

	MQL
	DBRO51
	MQA
	AND (7000)
	TAD I (SMGEJC)
	TAD I (RAGEJC)
	TAD I (RBGEJC)
	SNA CLA
	JMP MISC4	/NO, GO ON.
/
	CAL
	SEND		/YES, OPEN THE TRAY OUT INTERLOCK
	INLOCK
	INLMG1
MISC4,	CLB
	CDF 10
	DCA I (REJCNT)	/SET THE REJECT SHEET COUNTER TO 0.
	CDF CUR
	JMP START	/RETURN

	PAGE
/
MISC5,	CLB IAC		/INCREMENT THE SAMPLE TRAY LOCKED
	CDF 10
	TAD I (SMTLKD)	/IN COUNTER.
	SPA SNA
	DCA I (SMTLKD)
	SZL CLA
	DCA I (SMTLKF)
	CDF CUR
	CLB IAC		/HAS THE RECALIBRATE DELAY TIMED
	TAD INSPDY	/OUT ?
	SPA SNA
	DCA INSPDY
	SNL CLA
	JMP MISC6	/NO, RETURN.

	CDF 10
	TAD I (SHUTDY)	/YES, HAS THE SHUTTER OPENING DELAY
	CDF CUR
	SNA CLA		/TIMED OUT ?
	JMP .+4		/YES, GO ON.
	CLB CMA		/NO, RESET THE RECAL DELAY. THIS 
	DCA INSPDY	/WILL FORCE A RECAL AFTER THE
			/SHUTTER IS OPEN.
	JMP MISC6	/RETURN.

	TAD (400)	/YES, HIT THE END OF SPLICE
	DBSO55		/RECALIBRATE LINE.
	CLB CMA RTL
	DCA INSPDY	/HOLD THE LINE DOWN FOR 13.2
	ISZ INSPDY	/MICROSECONDS.
	JMP .-1
	TAD (400)	/CLEAR THE RECALIBRATE LINE.
	DBCO55
	CDF 50
	CLB IAC		/SET THE RECALIBRATE FLAG FOR
	DCA I (DIGREC)	/DIGITAL SELF CHECK.
	CDF CUR

MISC6,	CLB IAC		/HAS THE PARTIAL BOX MESSAGE
	TAD PARBMG	/DISPLAY TIMED OUT ?
	SPA SNA
	DCA PARBMG
	SNL CLA
	JMP MISC7	/NO, EXIT
	CAL
	SEND		/YES, ASK FOR OUR MESSAGE TO
	CRTMSG		/BE REMOVED
	MISMG5

MISC7,	JMP START	/ALL DONE, EXIT

/
INSPDY,	0		/RECAL DELAY COUNTER
MISMG1,	ZBLOCK 3	/CLEAR MACHINE CHECK CRT LINE
	CRTH23

MISMG2,	ZBLOCK 3	/MACHINE CHECK MESSAGE
	CRTH22

MISMG3, ZBLOCK 3	/CLEAR SPLICE CRT LINE
	CRTH25

MISMG4, ZBLOCK 3	/SPLICE DETECTED MESSAGE
	CRTH24

MISMG5, ZBLOCK 3
	MOPM11+4000

INLMG1, ZBLOCK 3	/TRAY OUT INTERLOCK
	0400

	PAGE

	NOPUNCH		/F3COMM AND CRTTXT FOLLOWS
	XLIST 1