/2	NULL JOB FOR PDP8-A RUNNING RTS-8
	VERS=	1
	XLIST	1		/COPYRIGHT ALSO GIVEN IN PARAM.PA
/
/
/
/
/
/
/
/
/
/COPYRIGHT  (C)  1976 BY DIGITAL EQUIPMENT CORPORATION
/
/
/
/
/
/
/
/
/
/
/THE INFORMATION IN THIS DOCUMENT IS SUBJECT TO CHANGE WITHOUT NOTICE
/AND SHOULD NOT BE CONSTRUED AS A COMMITMENT BY DIGITAL EQUIPMENT
/CORPORATION.  DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPONSIBILITY
/FOR ANY ERRORS THAT MAY APPEAR IN THIS DOCUMENT.
/
/THE SOFTWARE DESCRIBED IN THIS DOCUMENT IS FURNISHED TO THE PURCHASER
/UNDER A LICENSE FOR USE ON A SINGLE COMPUTER SYSTEM AND CAN BE COPIED
/(WITH INCLUSION OF DIGITAL'S COPYRIGHT NOTICE) ONLY FOR USE IN SUCH
/SYSTEM, EXCEPT AS MAY OTHERWISE BE PROVIDED IN WRITING BY DIGITAL.
/
/DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPONSIBILITY FOR THE USE
/OR RELIABILITY OF ITS SOFTWARE ON EQUIPMENT THAT IS NOT SUPPLIED BY
/DIGITAL.
/
/
/
/
/
/
/
/
/
/
	XLIST	0	/LIST TASK
/S.R.	NOVEMBER 1975
/S.R.	OCTOBER, 1976
/	EQUALIZED TIMING

	TASK=NULL8A
	INIWT=0
	CUR=10
	FIELD CUR%10

	*3600


START,	TAD (DIGS
	DCA PTR
BUMPLP,	ISZ I PTR	/BUMP
	TAD I PTR
	TAD (-12
	SZA CLA
	JMP SET
	DCA I PTR	/BACK TO 0
	ISZ PTR
	JMP BUMPLP
SET,	DCA DIGS+4
	DCA A
	DCA B
	TAD (-4
	DCA KNT
	TAD (DIGS+3
	DCA PTR
SETLP,	TAD I PTR
	TAD (TBL1
	DCA P1
	TAD I PTR
	TAD (TBL2
	DCA P2
	TAD A
	CLL RAL
	RTL
	TAD I P1
	DCA A
	TAD B
	CLL RTL
	RAL
	TAD I P2
	DCA B
	STA
	TAD PTR
	DCA PTR
	ISZ KNT
	JMP SETLP
	TAD A
	CIA
	TAD B
	DCA BMINA
	TAD BMINA
	CIA
	DCA AMINB
	TAD (-20
	DCA KNT
	ISZ MQNUM
	TAD MQNUM
	7421
	CLA		/JUST IN CASE
	TAD A
LOOP,	TAD BMINA
	ISZ DUMMY
	NOP
	TAD AMINB
	ISZ INNER
	JMP LOOP
	ISZ KNT
	JMP LOOP
	CLA
	JMP START
DIGS,	0;0;0;0;0

MQNUM,	0
DUMMY,	0
PTR,	0
A,	0
B,	0
AMINB,	0
BMINA,	0
KNT,	0
P1,	0
P2,	0
INNER,	0
/8=6+7
/9=7+4

TBL1,	0;1;2;3;4;5;6;7;7;7
TBL2,	0;1;2;3;4;5;6;7;6;4
$