Directory of image this file is from
This file as a plain text file

/PERT, PROJECT EVALUATION AND REVIEW TECHNIQUE
/
/
/TESTING MAINLINE
START,	OPEN	;DEVICE SYS;FILENA ACTIVS.DA;ACTIVS
	GONEG	;OPENER
	OPEN	;DEVICE SYS;FILENA NODES.DA;NODES
	GONEG	;OPENER
	PRINT 12;TEXT '_START TIME='
	TYPIN K20
	PRINTU	;MASK	;8
	STORE2	;S
ST1,	PRINT 25;TEXT '_ENTER ACTIVITY NO,NODES_'
ST2,	GOSUB	;INP
	GONEG	;ST5
	CLRWDS	;3;K
	GOSUB	;PUTACT
	GOTO	;ST2
ST5,	GOSUB	;PRTALL
	CLRWDS	;2;TMIN
	GOSUB	;PROCESS	
	GOSUB	;PRTALL
	CLOSE	;FILENA ACTIVS.DA	;ACTIVS
	CLOSE	;FILENA NODES.DA	;NODES
	EXIT
OPENER,	PRINT 11;TEXT '_FILE ERROR'
	EXIT
/PROCESS ROUTINE
/
/FORWARD PASS, CALC. ES,EF FOR EACH ACTIVITY
/CALC. ET FOR EACH NODE
PROCESS,	0;0
	CLEARW	;BPASS
	CLRWDS	;3;K
PR5,	LOADIM	;1
	ADDTO	;K
	GOSUB	;GETACT
	GONEG	;PR9
	MOVE1	;INI	;INODE
	MOVE1	;FIN	;JNODE
	LOAD1	;INODE
	GOSUB	;GETNODE
	MOVE2	;ET	;ES
	LOAD2	;T
	ADD2	;ES
	STORE2	;EF
	LOAD1	;JNODE
	GOSUB	;GETNODE
	LOAD2	;EF
	SUBT2	;ET
	GOIF	;PR6	;PR6
	MOVE2	;EF	;ET
	GOSUB	;PUTNODE
PR6,	LOAD2	;EF
	SUBT2	;TMIN
	GOIF	;PR8	;PR8
	MOVE2	;EF	;TMIN
PR8,	GOSUB	;PUTACT
	GOTO	;PR5
/BACKWARD PASS
/CALC. LFN,LS,TS FOR EACH ACTIVITY
/CALC. LT FOR EACH MODE
PR9,	INCREM	;BPASS
PR10,	LOAD	;K
	SUBTIM	;1
	STORE	;K
	GOZERO	;PR12
	GOSUB	;GETACT
	GONEG	;PR10
	MOVE1	;INI	;INODE
	MOVE1	;FIN	;JNODE
	LOAD1	;JNODE
	GOSUB	;GETNODE
	MOVE2	;LT	;LFN
	LOAD2	;LFN
	SUBT2	;T
	STORE2	;LS
	LOAD1	;INODE
	GOSUB	;GETNODE
	LOAD2	;LT
	SUBT2	;LS
	GONEG	;PR11
	MOVE2	;LS	;LT
	GOSUB	;PUTNODE
PR11,	LOAD2	;LS
	SUBT2	;ES
	STORE2	;TS
	GOSUB	;PUTACT
	GOTO	;PR10
/
/CALC. FREE SLACK= ACTIV. TOTAL SLACK LESS FINISH NODE TOTAL SLACK
PR12,	CLRWDS	;3;K
PR14,	LOADIM	;1
	ADDTO	;K
	GOSUB	;GETACT
	GONEG	;PR20
	MOVE1	;FIN	;JNODE
	LOAD1	;JNODE
	GOSUB	;GETNODE
	LOAD2	;TS
	SUBT2	;LT
	ADD2	;ET
	STORE2	;FS
	GOSUB	;PUTACT
	GOTO	;PR14
/END OF PROCESS LOOP
PR20,	GOTO	;PROCESS
/
/
/PRINT DETAIL LINE
PRTLIN,	0;0
	PRINT 1;TEXT '_'
	LOAD1	;ACTNUM
	PRINTU	;MASK	;6
	LOAD1	;INI
	PRINTU	;MASK	;6
	LOAD1	;FIN
	PRINTU	;MASK	;6
	CLEARW	;COUNT
PLIN,	LOADX1	;COUNT
	LOAD2	;T
	SIGN2
	PRINTU	;MASK	;6
	DO	;PLIN	;COUNT	;2;12
	PRINTX	;DESCR	;20
	GOTO	;PRTLIN
/
/PRINT ALL ACTIVITIES
PRTALL,	0;0
	CLRWDS	;3;K
PRTA,	LOADIM	;1
	ADDTO	;K
	GOSUB	;GETACT
	GONEG	;PRTALL
	GOSUB	;PRTLIN
	GOTO	;PRTA
/
/FIND NODE IN ACC. ELSE MAKE NEW RECORD
GETNODE,	0;0
	STORE1	;TEMP
	READSQ	;NODES
	GONEG	;NONOD
	STORE2	;NODTEM
	GETREC	;NORCID
	GOIFZO	;NONO2	;BPASS
	MOVE2	;TMIN	;LT
NONO2,	LOAD1	;NORCID
	GOIFEQ	;NONOD	;-1
	GOTO	;GETNODE
NONOD,	CLEARW	;NORCID
	MOVE2	;S	;ET
	LOAD2	;NODTEM
	PUTREC	;NORCID
	WRITE
	GOTO	;GETNODE
PUTNODE,	0;0
	LOAD1	;TEMP
	READSQ	;NODES
	INCREM	;NORCID
	PUTREC	;NORCID
	WRITE
	GOTO	;PUTNODE
TEMP,	0
NODP,	0
NODTEM,	0;0
/NODES RECORD 3000 RECORDS OF 5 WORDS
NORCID,	0
ET,	0;0
LT,	0;0
/
/GET ACTIVITY RECORD
GETACT,	0;0
	LOAD	;K
	READSQ	;ACTIVS
	GONEG	;GETACT
	GETREC	;ACRCID
	LOAD1	;ACTNUM
	GOIFEQ	;ENDACT	;-1
	GOTO	;GETACT
ENDACT,	SIGN1
	GOTO	;GETACT
PUTACT,	0;0	/PUT RECORD BACK
	LOAD	;K
	READSQ	;ACTIVS
	GONEG	;PUTACT
	PUTREC	;ACRCID
	LOAD	;K
	GOZERO	;PUTA2
	WRITE
	GOTO	;PUTACT
PUTA2,	WRITSQ
	GOTO	;PUTACT
/
/
/
/ WORK AREAS
MASK,	TEXT '        0-'
BPASS,	0
INODE,	0
JNODE,	0
K,	0;0;0
COUNT,	0
D,	0;0
S,	0;0
TMIN,	0;0
/
/ACTIVITY FILE RECORD
ACRCID,	0
ACTNUM,	0
INI,	0	/INITIAL NODE
FIN,	0	/FINAL NODE
T,	0;0	/TIME FOR ACTIVITY
ES,	0;0	/EARLIEST START
EF,	0;0	/EARLIEST FINISH
LS,	0;0	/LATEST START
LFN,	0;0	/LATEST FINISH
TS,	0;0	/TOTAL SLACK
FS,	0;0	/FREE SLACK
DESCR,	ZBLOCK 10	/20 CHARS
	ZBLOCK 5
			/32 WORDS LONG
/
/TEMP INPUT ROUTINE
INP,	0;0
INP2,	PRINT 1;TEXT '_'
	TYPIN K30
	GONEG	;INP
	STORE1	;ACTNUM
	CLRWDS	;16;INI
	PRINTU	;MASK	;6
	TYPIN	K10
	PRINTU	;MASK	;6
	STORE1	;INI
	TYPIN	K10
	PRINTU	;MASK	;6
	STORE1	;FIN
	TYPIN K20
	PRINTU	;MASK	;8
	STORE2	;T
	TYPTEX	;DESCR	;20
	PRINT 4;TEXT ' OK?'
	YESNO	;INP2
	CLEAR
	GOTO	;INP
OCTAL
FIELD 0
*6200
ACTIVS,	ZBLOCK 11
NODES,	ZBLOCK 11
$