/ REJECT TRAY GATE HANDLERS			3/16/77
/
/
/%R	REJECT TRAY GATE HANDLERS
/
/
/%TW	THESE ROUTINES ARE CALLED DURING EACH SHEET AND
/	CHECK THE TRAY DESTINATION DATA IN THE DEFECT
/	MEMORY TABLE TO SEE IF THE SHEET NEARING A
/	REJECT GATE IS MARKED FOR THAT TRAY.  IF THE
/	SHEET IS NOT MARKED FOR THE REJECT TRAY, THAT
/	REJECT TRAY IS TURNED OFF AND THE ROUTINE EXITS.
/
/%TW	IF THE SHEET IS MARKED FOR A REJECT TRAY, THE
/	"GATE ON" TIMING DELAY FOR THAT GATE IS SET UP
/	BASED ON THE CURRENT MACHINE SPEED.  ONCE THE
/	TIMER IS SET, IT IS PROCESSED BY THE GATE TURN
/	ON ROUTINE, "GATEON" WHICH WILL TURN ON THAT
/	REJECT GATE AND TRAY AIR ON AT THE PROPER TIME.
/	IF THE REJECT TRAY IS OUT, THE SHEET IS IGNORED.
/	EJECTION OF THE REJECT TRAY, TURNING OFF OF THE
/	TRAY AIR, AND LIGHTING OF THE TRAY FILLING
/	INDICATOR ARE ALSO CONTROLLED HERE.





TASK=	RAGATE		/REJECT A TRAY GATE HANDLER
CUR=	RGATEFLD
INIWT=	RUNWT
VERS=	1


TASK2=	RBGATE		/REJECT B TRAY GATE HANDLER
CUR2=	CUR
INIWT2=	RUNWT
VERS2=	1



	FIELD RGATEFLD%10
	*RGATELOC
/
/
/
/%RP	REJECT A TRAY GATE CONTROL ROUTINE
/
/
START,	CLB IAC
	DCA RAGTON	/CLEAR THE REJECT A GATE ON DELAY.

	TAD RAGLOC	/GET THE DATA FROM THE MEMORY TABLE
	TAD MEMPTR	/ AT THE REJECT A GATE POSITION.
	AND (0177)
	TAD (MEMTBL)
	DCA RAGSCR

	TAD I RAGSCR	/IS THIS SHEET FOR REJECT A ?
	AND (0020)
	SNA CLA
	JMP RAG1	/NO, GO TURN OFF THE GATE VALVE.

	TAD RATFLG	/IS THE REJECT A TRAY OUT ?
	SZA CLA
	JMP RAG1	/YES, FORGET IT.

	TAD GATEDY	/SET UP THE REJECT A GATE ON DELAY.
	DCA RAGTON
	TAD (20)	/TURN ON THE REJECT A FILLING
	DBSO54		/ INDICATOR.
	AC7775		/-3
	DCA RAGAIR	/RESET THE REJECT A TRAY AIR ON
			/ DELAY.

	TAD I RAGSCR	/IS THIS TRAY MARKED TO EJECT ?
	SMA CLA
	JMP RAG2	/NO, GO ON.
	TAD (-4)	/SET UP THE TRAY EJECT DELAY.
	DCA RAGEJC
	JMP RAG2
/
RAG1,	AC2000		/TURN OFF THE REJECT A GATE VALVE.
	DBCO50

	CLB IAC		/HAS THE REJECT A TRAY AIR ON DELAY
	TAD RAGAIR	/ TIMED OUT ?
	SPA SNA
	DCA RAGAIR
	SNL CLA
	JMP .+3		/NO, GO ON.

	TAD (20)	/TURN OFF THE REJECT A TRAY AIR.
	DBCO50

	CLB IAC		/HAS THE REJECT A TRAY EJECT DELAY
	TAD RAGEJC	/ TIMED OUT ?
	SPA SNA
	DCA RAGEJC
	SNL CLA
	JMP RAG2	/NO, GO ON.

	AC2000		/EJECT THE REJECT A TRAY NOW.
	DBSO51
	DCA RATFLG	/SET THE REJECT A TRAY OUT FLAG.
	TAD (20)	/TURN OFF THE REJECT A FILLING
	DBCO54		/ INDICATOR.

RAG2,	CLB
	CAL		/ALL DONE, GO BACK TO SLEEP.
	SUSPND
	JMP START	/GO LOOK AT THE NEXT SHEET.


RAGAIR,	0		/REJECT A TRAY AIR ON DELAY COUNTER
RAGSCR,	0		/LOCAL TEMPORARY
/
/
/
/%RP	REJECT B STRAY GATE CONTROL ROUTINE
/
/
START2,	CLB IAC
	DCA RBGTON	/CLEAR THE REJECT B GATE ON DELAY.

	TAD RBGLOC	/GET THE DATA FROM THE MEMORY TABLE
	TAD MEMPTR	/ AT THE REJECT B GATE POSITION.
	AND (0177)
	TAD (MEMTBL)
	DCA RBGSCR

	TAD I RBGSCR	/IS THIS SHEET FOR REJECT B ?
	AND (0010)
	SNA CLA
	JMP RBG1	/NO, GO TURN OFF THE GATE VALVE.

	TAD RBTFLG	/IS THE REJECT B TRAY OUT ?
	SZA CLA
	JMP RBG1	/YES, FORGET IT.

	TAD GATEDY	/SET UP THE REJECT B GATE ON DELAY.
	DCA RBGTON
	TAD (10)	/TURN ON THE REJECT B FILLING
	DBSO54		/ INDICATOR.
	AC7775		/-3
	DCA RBGAIR	/RESET THE REJECT B TRAY AIR ON
			/ DELAY.

	TAD I RBGSCR	/IS THIS TRAY MARKED TO EJECT ?
	SMA CLA
	JMP RBG2	/NO, GO ON.
	TAD (-4)	/SET UP THE TRAY EJECT DELAY.
	DCA RBGEJC
	JMP RBG2
/
RBG1,	TAD (1000)	/TURN OFF THE REJECT B GATE VALVE.
	DBCO50

	CLB IAC		/HAS THE REJECT B TRAY AIR ON DELAY
	TAD RBGAIR	/ TIMED OUT ?
	SPA SNA
	DCA RBGAIR
	SNL CLA
	JMP .+3		/NO, GO ON.

	TAD (10)	/TURN OFF THE REJECT B TRAY AIR.
	DBCO50

	CLB IAC		/HAS THE REJECT B TRAY EJECT DELAY
	TAD RBGEJC	/ TIMED OUT ?
	SPA SNA
	DCA RBGEJC
	SNL CLA
	JMP RBG2	/NO, GO ON.

	TAD (1000)	/EJECT THE REJECT B TRAY NOW.
	DBSO51
	DCA RBTFLG	/SET THE REJECT B TRAY OUT FLAG.
	TAD (10)	/TURN OFF THE REJECT B FILLING
	DBCO54		/ INDICATOR.

RBG2,	CLB
	CAL		/ALL DONE, GO BACK TO SLEEP.
	SUSPND
	JMP START2	/GO LOOK AT THE NEXT SHEET.


RBGAIR,	0		/REJECT B TRAY AIR ON DELAY COUNTER
RBGSCR,	0		/LOCAL TEMPORARY

	PAGE

	/$=$=LHN=$=$