/ SAMPLE TRAY GATE HANDLER			3/26/77
/
/
/%RP	SAMPLE TRAY GATE CONTROL ROUTINE
/
/
/%TW	THIS ROUTINE IS CALLED DURING EACH SHEET AND
/	CHECKS THE TRAY DESTINATION DATA IN THE DEFECT
/	MEMORY TABLE TO SEE IF THE SHEET NEARING THE
/	SAMPLE GATE IS MARKED AS A SAMPLE. IF THE SHEET
/	IS NOT FOR THE SAMPLE TRAY, THE SAMPLE GATE IS
/	TURNED OFF AND THE ROUTINE EXITS.
/
/%TW	IF THE SHEET IS MARKED AS A SAMPLE, THE "GATE
/	ON" TIMING DELAY FOR THE SAMPLE GATE IS SET UP
/	BASED ON THE CURRENT MACHINE SPEED.  ONCE THE
/	TIMER IS SET, IT IS PROCESSED BY THE GATE TURN
/	ON ROUTINE, "GATEON" WHICH WILL TURN ON THE 
/	SAMPLE GATE AND TRAY AIR ON AT THE PROPER TIME.
/	IF THE SAMPLE TRAY IS OUT, THE SHEET IS IGNORED.
/	EJECTION OF THE SAMPLE TRAY AND TURNING OFF OF
/	THE TRAY AIR ARE ALSO CONTROLLED HERE.





TASK=	SMGATE		/SAMPLE TRAY GATE HANDLER
CUR=	SGATEFLD
INIWT=	RUNWT
VERS=	1



	FIELD SGATEFLD%10
	*SGATELOC
/
/
/
/%RP	SAMPLE TRAY GATE CONTROL ROUTINE
/
/
START,	CLB IAC
	DCA SMGTON	/CLEAR THE SAMPLE GATE ON DELAY.

	TAD SMGLOC	/GET THE DATA FROM THE MEMORY TABLE
	TAD MEMPTR	/ AT THE SAMPLE GATE POSITION.
	AND (0177)
	TAD (MEMTBL)
	DCA SMGSCR

	TAD I SMGSCR	/IS THIS SHEET A SAMPLE ?
	AND (0040)
	SNA CLA
	JMP SMG1	/NO, GO TURN OFF THE GATE VALVE.

	TAD SMTFLG	/IS THE SAMPLE TRAY OUT ?
	SZA CLA
	JMP SMG1	/YES, FORGET IT.

	TAD GATEDY	/SET UP THE SAMPLE GATE ON DELAY.
	DCA SMGTON
	AC7775		/-3
	DCA SMGAIR	/RESET THE SAMPLE TRAY AIR ON DELAY.

	TAD I SMGSCR	/IS THIS TRAY MARKED TO EJECT ?
	SMA CLA
	JMP SMG2	/NO, GO ON.
	TAD (-10)	/SET UP THE TRAY EJECT DELAY.
	DCA SMGEJC
	JMP SMG2
/
SMG1,	AC4000		/TURN OFF THE SAMPLE GATE VALVE.
	DBCO50

	CLB IAC		/HAS THE SAMPLE TRAY AIR ON DELAY
	TAD SMGAIR	/ TIMED OUT ?
	SPA SNA
	DCA SMGAIR
	SNL CLA
	JMP .+3		/NO, GO ON.

	TAD (40)	/TURN OFF THE SAMPLE TRAY AIR.
	DBCO50

	CLB IAC		/HAS THE SAMPLE TRAY EJECT DELAY
	TAD SMGEJC	/ TIMED OUT ?
	SPA SNA
	DCA SMGEJC
	SNL CLA
	JMP SMG2	/NO, GO ON.

	AC4000		/EJECT THE SAMPLE TRAY NOW.
	DBSO51
	DCA SMTFLG	/SET THE SAMPLE TRAY OUT FLAG.

SMG2,	CLB
	CAL		/ALL DONE, GO BACK TO SLEEP.
	SUSPND
	JMP START	/GO LOOK AT THE NEXT SHEET.


SMGAIR,	0		/SAMPLE TRAY AIR ON DELAY COUNTER
SMGSCR,	0		/LOCAL TEMPORARY

	PAGE

	/$=$=LHN=$=$