/76
/
/
/%R	CHECK THE STATUS OF THE STACKER TRAYS
/
/%TW	COME HERE ONCE PER CHOP VIA THE JUMP TABLE TO 
/	MONITOR THE STATUS OF THE STACKER TRAYS.  TURN
/	ON THE "TRAY NEEDED" INDICATORS AS REQUIRED AND
/	STOP THE FINISHING MACHINE IF NEEDED TRAYS
/	ARE NOT RETURNED IN TIME.  WHEN ANY "TRAY NEEDED"
/	INDICATOR IS FLASHING, THE "TRAY OUT" MESSAGE IS 
/	DISPLAYED ON THE OPERATOR'S CRT, AND THE ALERT
/	ALARM IS SOUNDED.
/
/%TW	THE SAMPLE TRAY NEEDED LIGHT WILL COME ON AFTER
/	THE TRAY HAS BEEN OUT FOR 90 (DECIMAL) CHOPS.
/	IF THE SAMPLE TRAY IS OUT FOR MORE THAN 180
/	(DECIMAL) CHOPS, THE MACHINE WILL STOP.
/	NORMAL SAMPLING IS INTERRUPTED WHENEVER THE SAMPLE
/	TRAY IS OUT.
/
/%TW	WHEN A REJECT TRAY IS EJECTED, IT MAY STAY OUT
/	UNTIL THE ACTIVE REJECT TRAY SHEET COUNT IS
/	WITHIN 50 OF THE TRAY CAPACITY BEFORE THE TRAY
/	NEEDED INDICATOR COMES ON.  IF THE TRAY IS STILL
/	OUT WHEN THE ACTIVE REJECT TRAY GETS WITHIN 15
/	SHEETS OF ITS CAPACITY, THE MACHINE WILL STOP.
/
/%TW	THE PRODUCT TRAY ARE HANDLED THE SAME AS THE 
/	REJECT TRAYS.
/
/
TRAYCK,	0
	CLB
	DBRI52
	AND P200
	SZA CLA
	JMP I TRAYCK
	DBRI51		/READ THE TRAY POSITION DATA
	AND P7700	/ARE ANY STACKER TRAYS OUT ?
	SNA
	JMP I TRAYCK	/NO, RETURN
	CLL RAL
	DCA WKA		/YES, SAVE THE TRAY OUT DATA FOR LATER
	SNL CLA		/IS THE SAMPLE TRAY OUT ?
	JMP TRAY1-1	/NO
	ISZ TRAYZ1	/YES, INCREMENT THE TRAY OUT COUNTER
	TAD TRAYZ1	/HAS THE TRAY BEEN OUT FOR MORE THAN 90
	TAD (-132)	/CHOPS, ABOUT 100 FEET ?
	SPA CLA
	JMP TRAY1	/NO, GO ON
/77
	TAD P40		/YES,  GO SET UP TO TURN ON THE SAMPLE
	JMS TRAY5	/TRAY NEEDED INDICATOR.
	TAD TRAYZ1
	TAD (-264)	/HAS THE TRAY BEEN OUT FOR MORE THAN
	SPA CLA		/180 CHOPS, ABOUT 200 FEET ?
	JMP TRAY1	/NOT YET, GO ON
	TAD P400	/YES, GO OPEN THE "TRAY OUT" INTERLOCK
	JMS INLOCK
	SKP
	DCA TRAYZ1	/CLEAR THE SAMPLE TRAY OUT CHOP COUNTER

TRAY1,	TAD WKA		/ARE EITHER OF THE REJECT TRAYS OUT ?
	CLL RAL
	SMA SNL CLA
	JMP TRAY2	/NO, GO ON TO THE PRODUCT TRAYS
	TAD REJCNT	/YES, DOES THE ACTIVE REJECT TRAY
	TAD (62)	/CONTAIN MORE THAN 75 SHEETS ?
	SPA CLA
	JMP TRAY2	/NO, GO ON
	TAD REJFLG	/YES, SET "TRAY NEEDED" LIGHT FOR THE
	SZA CLA		/REJECT TRAY WHICH IS OUT
	TAD P10		/REJECT A TRAY OUT
	TAD P10		/REJECT B TRAY OUT
	JMS TRAY5	/GO SET UP TO TURN ON THE REQUIERED
			/REJECT TRAY NEEDED INDICATOR.
	TAD REJCNT	/DOES THE ACTIVE REJECT TRAY CONTAIN
	TAD (17)	/MORE THAN 110 SHEETS ?
	SPA CLA
	JMP TRAY2	/NO, GO ON
	TAD P400	/YES, GO OPEN THE "TRAY OUT" INTERLOCK
	JMS INLOCK

TRAY2,	TAD WKA		/ARE ANY OF THE PRODUCT TRAYS OUT ?
	CLL RAL
	CLL RAL
	SNA CLA
	JMP TRAY4	/NO, GO ON
	TAD PROCNT	/CONTAIN MORE THAN 75 SHEETS ?
	TAD (62)
	SPA CLA
	JMP TRAY4	/NO, GO ON
	DBRI51		/YES, SET UP TO TURN ON THE PROPER
	BSW		/PRODUCT TRAY NEEDED INDICATOR.
	AND (7)
	JMS TRAY5
	TAD PROCNT	/DOES THE ACTIVE PRODUCT TRAY CONTAIN 
	TAD (17)	/MORE THAN 110 SHEETS ?
	SPA CLA
	JMP TRAY4	/NO, GO ON
TRAY3,	TAD P400	/YES, GO OPEN THE "TRAY OUT" INTERLOCK
	JMS INLOCK
/78
TRAY4,	CLB		/IS ANY "TRAY NEEDED" INDICATOR ON ?
	TAD TRAYNF
	SNA CLA
	JMP I TRAYCK	/NO, RETURN
	TAD TRAFLG	/YES, IS THE TRAY OUT ALARM FLAG SET ?
	SZA CLA
	JMP I TRAYCK	/YES, RETURN.
	DBRI52		/NO, ARE THE FIELD INPUTS DISABLED ?
	AND P40
	SZA CLA
	JMP I TRAYCK	/YES, RETURN.
	CIF 30		/NO, GO CUE THE "TRAY OUT" MESSAGE
	JMS I (CRTMSG)	/FOR THE CRT DISPLAY.
	CRTM04
	CLB IAC
	DCA TRAFLG	/SET THE TRAY OUT ALARM FLAG
	JMP I TRAYCK	/RETURN
/
/
/	SUBROUTINE TO "OR" BITS INTO THE TRAY NEEDED FLAG.
/
/
TRAY5,	0
	MQL		/PUT THE NEW BIT IN THE M/Q REGISTER.
	TAD TRAYNF	/GET THE OLD TRAY NEEDED FLAG
	MQA		/"OR" IN THE NEW TRAY NEEDED BIT AND
	DCA TRAYNF	/PUT THE DATA BACK IN THE FLAG.
	JMP I TRAY5	/RETURN

TRAYZ1,	0